pthread 和 x64 程序集中主线程执行的代码之间的行为差​​异

Question

在编写一些 x64 程序集时，我偶然发现了一些奇怪的东西。函数调用在主线程上执行时工作正常，但在作为 pthread 执行时会导致分段错误。起初我以为我使堆栈无效，因为它只在第二次调用时出现段错误，但这与它在主线程上正常工作但在新生成的线程上崩溃的事实不匹配。

来自 gdb：

[Thread debugging using libthread_db enabled]
Using host libthread_db library "/lib/x86_64-linux-gnu/libthread_db.so.1".
Value: 1337
Value: 1337
[New Thread 0x7ffff77f6700 (LWP 8717)]
Return value: 0
Value: 1337

Program received signal SIGSEGV, Segmentation fault.
[Switching to Thread 0x7ffff77f6700 (LWP 8717)]
__printf (format=0x600570 <fmt> "Value: %d\n") at printf.c:28
28  printf.c: No such file or directory.

有没有人知道这里会发生什么？

extern printf

extern pthread_create
extern pthread_join
extern pthread_exit


section .data
  align     4
  fmt       db    "Value: %d", 0x0A, 0
  fmt_rval  db    "Return value: %d", 0x0A, 0
  tID         dw    0

section .text
  global _start

_start:
  mov   rdi, 1337
  call  show_value
  call  show_value        ; <- this call works fine

  ; CREATE THREAD
  mov     ecx, 0                ; function argument
  mov   edx, thread_1       ; function pointer
  mov     esi, 0                ; attributes
  mov   rdi, tID              ; pointer to threadID
  call  pthread_create

  mov   rdi, rax
  call  show_rval

  mov   rsi, 0              ; return value
  mov     rdi, [tID]          ; id to wait on
  call  pthread_join

  mov   rdi, rax
  call  show_rval

  call exit

thread_1:
  mov   rdi, 1337
  call  show_value
  call  show_value     ; <- this additional call causes a segfault
  ret


show_value:
  push    rdi

  mov     rsi, rdi
  mov     rdi, fmt
  call    printf

  pop       rdi
  ret

show_rval:
  push    rdi

  mov     rsi, rdi
  mov     rdi, fmt_rval
  call    printf

  pop       rdi
  ret

exit:
  mov     rax, 60
  mov     rdi, 0
  syscall

该二进制文件是在 Ubuntu 14.04（当然是 64 位）上生成的，其中包含：

nasm -felf64 -g -o $1.o $1.asm
ld  -I/lib64/ld-linux-x86-64.so.2 -o $1.out $1.o -lc -lpthread

Answer 1

采用可变数量参数的函数printf需要正确设置RAX寄存器。您需要将其设置为使用的向量寄存器的数量，在您的情况下为 0。来自第 3.2.3 节System V 64 位 ABI中的参数传递：

雷克斯

• 临时登记册；
• 使用可变参数传递有关使用的向量寄存器数量的信息；
• 第一个返回寄存器

第 3.5.7 节包含有关采用可变数量参数的函数的参数传递机制的更多详细信息。该部分说：

当调用采用可变参数的函数时，必须将 %rax 设置为在向量寄存器中传递给函数的浮点参数总数。

修改您的代码以在调用中将RAX设置为零printf：

show_value:
  push    rdi

  xor     rax, rax     ; rax = 0
  mov     rsi, rdi
  mov     rdi, fmt
  call    printf

  pop       rdi
  ret

你有类似的问题 show_rval

另一项观察是您可以通过使用GCC而不是LD来简化链接您的可执行文件

我建议重命名_start，以main和简单的使用GCC连接最后的可执行文件。GCC的C运行时代码将提供一个_start标签，用于正确初始化C运行时，在某些情况下可能需要这样做。当C运行时代码完成初始化时，它会传输（通过CALL）到标签main。然后，您可以使用以下命令生成可执行文件：

nasm -felf64 -g -o $1.o $1.asm
gcc -o $1.out $1.o -lpthread

我不认为这与您的问题有关，但更像是仅供参考。

由于没有为呼叫正确设置RAX，printf在某些情况下可能会发生不需要的行为。在这种情况下，在具有线程的环境中没有为调用正确设置RAX的值printf会导致分段错误。没有线程的代码碰巧能工作，因为你很幸运。