ANTLR4 RegEx 词法分析器模式

Question

我正在 XSD 内为 RegEx 开发 Regx 解析器。我之前的问题在这里描述：ANTLR4 parsing RegEx

从那以后我就把词法分析器和解析器分开了。现在我在解析括号内的括号时遇到问题。它们应该被视为括号内的字符和括号外的分组标记。这是我的词法分析器语法：

lexer grammar RegExLexer;

Char    : ALPHA ;
Int     : DIGIT ;

LBrack  : '[' ;//-> pushMode(modeRange) ;
RBrack  : ']' ;//-> popMode ;
LBrace  : '(' ;
RBrace  : ')' ;
Semi    : ';' ;
Comma   : ',' ;
Asterisk: '*' ;
Plus    : '+' ;
Dot     : '.' ;
Dash    : '-' ;
Question: '?' ;
LCBrace : '{' ;
RCBrace : '}' ;
Pipe    : '|' ;
Esc     : '\\' ;

WS : [ \t\r\n]+ -> skip ;

fragment DIGIT : [0-9] ;
fragment ALPHA : [a-zA-Z] ;

这是一个例子：

[0-9a-z()]+

我觉得我应该使用括号上的模式来改变 ALPHA 片段的行为。如果我复制该片段，则会收到一条错误消息，指出我不能两次声明该声明。我已阅读有关此的参考资料，但我仍然不明白我应该做什么。

如何实施这些模式？

Answer 1

以下是如何使用 ANTLR4 的词法模式创建上下文敏感词法分析器的快速演示：

lexer grammar RegexLexer;

START_CHAR_CLASS
 : '[' -> pushMode(CharClass)
 ;

START_GROUP
 : '('
 ;

END_GROUP
 : ')'
 ;

PLAIN_ATOM
 : ~[()\[\]]
 ;

mode CharClass;

END_CHAR_CLASS
 : ']' -> popMode
 ;

CHAR_CLASS_ATOM
 : ~[\r\n\\\]]
 | '\\' .
 ;

生成词法分析器后，您可以使用以下类来测试它：

import org.antlr.v4.runtime.ANTLRInputStream;
import org.antlr.v4.runtime.Token;

public class Main {
    public static void main(String[] args) {
        RegexLexer lexer = new RegexLexer(new ANTLRInputStream("([()\\]])"));
        for (Token token : lexer.getAllTokens()) {
            System.out.printf("%-20s %s\n", RegexLexer.VOCABULARY.getSymbolicName(token.getType()), token.getText());
        }
    }
}

如果您运行这个 Main 类，以下内容将打印到您的控制台：

START_GROUP          (
START_CHAR_CLASS     [
CHAR_CLASS_ATOM      (
CHAR_CLASS_ATOM      )
CHAR_CLASS_ATOM      \]
END_CHAR_CLASS       ]
END_GROUP            )

正如您所看到的，(和)在字符类外部和在字符类内部的标记方式不同。