如何使用RTTI检查或更改存在哪些设置元素？

Question

我希望能够从ST:TElementSet检查,添加和删除T:TElements.

type
  TElements = (elA, elB, elC);
  TElementSet = set of TElements;

  TMyClass<T, ST> = class
    property SetValue:ST;
  end;

泛型不能让我告诉编译器T是枚举类型而ST是一组T.

RTTI使我能够将类型识别为tkEnumeration和tkSet - 但我不确定是否可以使用RTTI在两者之间建立严格的连接.这并不重要,因为我只需要通过序数值来旋转设置位.

问题是:我可以安全地使用泛型和RTTI,如果是这样 - 如何？

可以理解现有技术的示例和/或参考.

Answer 1

假设我们只处理连续的枚举(因为其他人没有正确的typeinfo而且无法轻易处理),我们可以在没有typeInfo/RTTI的情况下完成此操作.

枚举为枚举中的元素设置了一个掩码.

例如,集合[elA,elC]等于00000101(从右到左)等于5.

要设置的位的索引等于enum + 1的序数值(因为第一个枚举值的序数为0,但它是第1位).

由于我们不能在Delphi中设置单独的位而只能设置Bytes,因此我们需要计算正确的值,这将导致此代码包括:

set [enum div 8]:= set [enum div 8]或(1 shl(enum mod 8))

由于集合不能包含超过256个元素,因此我们还可以假设枚举值始终是字节的大小.处理不从0开始的枚举将需要更多代码并读取typeinfo的最小值和最大值

这里有一些测试代码 - 我使用绝对技巧,但你也可以使用hardcast:

program GenericEnumSet;

{$APPTYPE CONSOLE}

type
  TMyEnum = (elA, elB, elC);
  TMySet = set of TMyEnum;

  TEnumSet<TEnum,TSet> = record
    value: TSet;
    procedure Include(const value: TEnum); inline;
    procedure Exclude(const value: TEnum); inline;
  end;

procedure _Include(var setValue; const enumValue);
var
  localEnum: Byte absolute enumValue;
  localSet: array[0..31] of Byte absolute setValue;
begin
  localSet[localEnum div 8] := localSet[localEnum div 8] or (1 shl (localEnum mod 8));
end;

procedure _Exclude(var setValue; const enumValue);
var
  localEnum: Byte absolute enumValue;
  localSet: array[0..31] of Byte absolute setValue;
begin
  localSet[localEnum div 8] := localSet[localEnum div 8] and not (1 shl (localEnum mod 8));
end;

procedure TEnumSet<TEnum, TSet>.Include(const value: TEnum);
begin
  _Include(Self.value, value);
end;

procedure TEnumSet<TEnum, TSet>.Exclude(const value: TEnum);
begin
  _Exclude(Self.value, value);
end;

var
  mySet: TEnumSet<TMyEnum,TMySet>;
  myEnum: TMyEnum;
begin
  mySet.value := [];
  for myEnum := Low(TMyEnum) to High(TMyEnum) do
  begin
    mySet.Include(myEnum);
    Assert(mySet.value = [Low(TMyEnum)..myEnum]);
  end;
  for myEnum := Low(TMyEnum) to High(TMyEnum) do
  begin
    mySet.Exclude(myEnum);
    if myEnum < High(TMyEnum) then
      Assert(mySet.value = [Succ(myEnum)..High(TMyEnum)])
    else
      Assert(mySet.value = []);
  end;
  Readln;
end.

我将实现其他方法和错误检查留作读者练习.