cmake-全局链接器标志设置（针对目录中的所有目标）

Question

我想将链接器标志传递给项目中的所有子项目（子目录CMakeList）。

在切换到新的cmake 3.3之前，我使用了运行良好的以下代码（cmake 3.2），为编译和链接添加了标志：

set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -stdlibc++")
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -stdlibc++")

在cmake 3.3中，它不再起作用，并且仅在编译步骤设置标志。我更新了CMakeList以使用更“现代”的cmake语法：

set(MY_DEBUG_OPTIONS -g -stdlib=libstdc++ -Wfatal-errors)
set(MY_RELEASE_OPTIONS -O3 -stdlib=libstdc++ -Wfatal-errors)

add_compile_options(
  "$<$<CONFIG:DEBUG>:${MY_DEBUG_OPTIONS}>"
  "$<$<CONFIG:RELEASE>:${MY_RELEASE_OPTIONS}>")

这为所有子项目设置了编译标志，是否对链接程序标志采取了类似的方法？我知道可以使用target_link_libraries命令在目标基础上添加链接器标志，但找不到其他任何东西。

我尝试使用CMAKE_SHARED_LINKER_FLAGS变量（以及exe，模块等对应的var）没有成功。

更新：

事实证明，这与cmake版本无关CMAKE_CXX_FLAGS_XXX，除了第一个make命令外，变量都可以正常工作。如果make第二次运行（在CmakeList中进行了修改），则会显示标志。

我想我在使用简单的CMakeList进行测试时找到了一个解决方案：如果在project命令后声明了标志，它就可以按预期工作。我不知道这是cmake本身的要求，还是只是怪异的行为。

cmake_minimum_required (VERSION 3.2)

set(PROJECT Test_Project)

# Not working (on first run)
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -stdlib=libstdc++ -Wfatal-errors")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} -g -stdlib=libstdc++ -Wfatal-errors")
set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} -O3 -stdlib=libstdc++ -Wfatal-errors")

project(${PROJECT})

# Declare here instead...

add_executable(Test test.cpp)

MESSAGE( STATUS "Config flags : " ${CMAKE_CXX_FLAGS_RELEASE})

使用：

cmake -G "Unix Makefiles" -DCMAKE_BUILD_TYPE=Release .

Answer 1

您的问题与/与特定的 CMake 版本无关。

CMake 中的所有链接器/编译器标志变量都是一样的。因为这些变量是缓存变量并使用project()/enable_language()命令设置（详细信息请参见此处），您要么必须

1. set(... CACHE ...)在project()命令之前预填充缓存
2. 通常使用set(... CACHE ... FORCE)强制/覆盖
3. set()在project()命令之后移动以隐藏或附加到缓存变量

以下是CMAKE_EXE_LINKER_FLAGS显示所有三种变体的示例：

CMakeLists.txt

cmake_minimum_required(VERSION 2.8)

# 1. prefill
#set(CMAKE_EXE_LINKER_FLAGS "-Wl,-Map=output.map" CACHE INTERNAL "")

project(Test_Project CXX)

# 2. force
set(CMAKE_EXE_LINKER_FLAGS "-Wl,-Map=output.map" CACHE INTERNAL "" FORCE)

# 3. hide
#set(CMAKE_EXE_LINKER_FLAGS "-Wl,-Map=output.map")
# 3. or append
#set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-Map=output.map")

# TODO: Remove, this is just for testing
file(WRITE "foo.cpp" "int main() {}") 

add_executable(${PROJECT_NAME} foo.cpp)

无论这些变量的值在您的任何给定CMakeLists.txt文件的末尾是什么，都将CMakeLists.txt作为默认值应用于同一文件中的所有相应目标（请参阅CMAKE - 设置库的编译标志和设置和使用变量的 CMake 语法是什么？）。

第一个变体的缺点是它实际上只是初始值。第二个和第三个变体很可能需要一个if (CMAKE_COMPILER_IS_GNUCXX)，所以我更喜欢第二个变体，将这些设置移动到它自己的初始缓存文件中：

MyGNUSettings.cmake

set(CMAKE_CXX_FLAGS "-stdlib=libstdc++ -Wfatal-errors" CACHE INTERNAL "" FORCE)
set(CMAKE_CXX_FLAGS_DEBUG "-g" CACHE INTERNAL "" FORCE)
set(CMAKE_CXX_FLAGS_RELEASE "-O3" CACHE INTERNAL "" FORCE)
set(CMAKE_EXE_LINKER_FLAGS "-Wl,-Map=output.map" CACHE INTERNAL "" FORCE)

使用例如

cmake -G "Unix Makefiles" -C MyGNUSettings.cmake -DCMAKE_BUILD_TYPE=Release  .

是的 - 对于全局和每个编译器设置 - 我更喜欢全局缓存变量而不是add_compile_options()命令。我认为add_compile_options()没有替换全局变量，它主要是为了防止人们在add_definitions()命令中放置编译器选项而引入的。