Fortran 90中二进制文件数据读取不正确

Question

我正在阅读用不同程序编写的二进制文件.开放和阅读的陈述似乎是成功的,我在之前的帖子中得到了帮助.但是,读入的数据与文件不匹配.我已经初始化了2D数组但是在读入文件之后,数组不保存数据,但看起来是一个未初始化的数组.我已经发布了下面的代码,用于读取和打印出数组.有什么想法吗？

       allocate(dummy(imax,jmax))

       dummy = 0.0
       open(unit=io, file=trim(input), access='direct', iostat=ioer, &
            status='old', action='READ', recl=imax*jmax*4)

       if(ioer/=0) then
        print*, 'Cannot open file'
       else
        print*,'success opening file'
       end if

       j=0
       k=0
       read(unit=io,rec=1,iostat=ioer) dummy!(j,k)
       if(ioer/=0) then
         print*, 'Cannot open file'
       else
         print*,'success opening file'
       end if

       size: do j=1, imax
           do k=1, jmax
             if(dummy(j,k) > 0.) print*,'i-',j,'j-',k,'frp-',dummy(j,k)
           end do 
       end do size
       print*,'j-',j,'k-',k

这是原始写的:

  out_file = trim(output_dir)//'SEVIRI_FRP_.08deg_'//trim(season)//'.bin'

  print*, out_file
  print*, i_max,' i_max,',j_max,' j_max'

  open (io, file = out_file, access = 'direct', status = 'replace', recl = i_max*j_max*4)

  write(io, rec = 1) sev_frp
  write(io, rec = 2) count_sev_frp
  write(io, rec = 3) sum_sev_frp

这是打印出来的一部分:

  i-         600 j-         213 frp-  4.1759680E-08
  i-         600 j-         220 frp-  8.8314310E-18
  i-         600 j-         221 frp-  2.7975964E-36
  i-         600 j-         246 frp-   461506.1    
  i-         600 j-         254 frp-   19.79016    
  i-         600 j-         255 frp-  2.0032716E-22
  i-         600 j-         260 frp-  1.0871451E+24
  j-         601 k-         401

这与它应该是相同的部分:

  i-         600 j-         213 frp-   13.6999998    
  i-         600 j-         218 frp-   63.2000008    
  i-         600 j-         220 frp-   29.1416683    
  i-         600 j-         221 frp-   31.8032303    
  i-         600 j-         229 frp-   39.5000000    
  i-         600 j-         232 frp-   55.4714279    
  i-         600 j-         246 frp-   54.2200012    
  i-         600 j-         254 frp-   13.1636362    
  i-         600 j-         255 frp-   10.9028578    
  i-         600 j-         258 frp-   24.6888885    
  i-         600 j-         259 frp-   13.5619040    
  i-         600 j-         260 frp-   11.4000006    
  n-         601 m-         401

声明/分配声明:

 real, allocatable, dimension(:,:) :: dummy

 allocate(dummy(imax,jmax))

 dummy = 0.0

这些在写/读中都是相同的,imax并且600 jmax是400

Answer 1

正如MSB在评论中建议的那样,这是正在编写文件的机器和正在阅读的机器之间的字节序问题.

要查看此内容,请查看同一数组索引处这些值的差异:

i-         600 j-         213 frp-  4.1759680E-08
i-         600 j-         213 frp-   13.6999998 

如果第一个值4.1759680E-08是小端,则其十六进制表示为33 33 5B 41.当在大端机器上读取这个精确表示时,它读为13.6999998.如果第一个值是大端和第二个小端,则问题是相同的,除了十六进制表示41 5B 33 33.要解决此问题,您需要确定写入文件的计算机的endianess.

gfortran和英特尔Fortran(以及其他可能的其他)都提供了扩展,允许您指定未格式化的输入文件的字节顺序.如果编写该文件的计算机是big endian,请open在阅读时将其添加到语句中:

convert='big_endian'

如果编写该文件的机器是小端,请open在读取时将其添加到语句中:

convert='little_endian'

您表示您正在使用小端机器进行编写,因此为了在大端机器上读取它,请将其打开为:

open(unit=io, file=trim(input), access='direct', iostat=ioer, &
        status='old', action='READ', recl=imax*jmax*4, &
        convert='little_endian')

你的阅读应该正常.