在Android中更改按钮的字体大小,同时保留原生状态

Question

我想改变Button的字体大小.我用过这里的解决方案

import QtQuick 2.2
import QtQuick.Controls 1.2
import QtQuick.Controls.Styles 1.2

Rectangle {
  id: container
  width: 800
  height: 800

  Button {
    id: cmdQuit
    text: qsTr("Quit")
    width: 100
    height: 100
    style: ButtonStyle {
      label: Text {
        renderType: Text.NativeRendering
        verticalAlignment: Text.AlignVCenter
        horizontalAlignment: Text.AlignHCenter
        font.pointSize: 20
        text: cmdQuit.text
      }
    }
  }
}

不幸的是,当我这样做时,我失去了Android原生外观,并获得了后备基础外观.有没有办法在不丢失Android上的原生样式的情况下更改字体大小？

我想改变单个按钮的外观,并希望其他按钮保持不变.我正在使用Qt5(C++)和QML.我不想要一个涉及复制整个QtQuick/Controls/Styles/Android文件夹的解决方案 - 我可以自己做但是很糟糕

Answer 1

警告:此解决方案依赖于修改内部对象,并不保证可以跨不同的Qt版本或平台工作

如果您只想修改未公开的对象的属性,您仍然可以使用(或/ )的children属性访问它.Itemresourcesdata

一个方便调用的函数Component.omCompleted是转储一个层次结构的函数Item,这里是一个示例实现:

function dumpHierarchy(item, level) {
    level = level | 0;
    for (var index = 0; index < item.children.length; ++index) {
        var child = item.children[index];
        print(Array(level*2 + 1).join(" ")+ index +": "+child);
        dumpHierarchy(child, level+1);
    }
}

以及它在Android和Qt 5.5上输出的内容Button:

0: QQuickLoader(0xab87c768)
  0: QQuickLoader_QML_44(0xab7a84f0)
  1: QQuickItem_QML_53(0xab8c8d60)
    0: DrawableLoader_QMLTYPE_51(0xab8bb088)
      0: StateDrawable_QMLTYPE_65(0xab949420)
        0: DrawableLoader_QMLTYPE_51(0xab936ea0)
          0: NinePatchDrawable_QMLTYPE_67(0xab955c90)
            0: QQuickAndroid9Patch_QML_68(0xab913608)
        1: QQuickLoader_QML_66(0xab924838)
    1: QQuickRowLayout(0xab8b03a0)
      0: QQuickImage(0xab8b0960)
      1: LabelStyle_QMLTYPE_50(0xab8c1758)
1: QQuickMouseArea_QML_46(0xab887028)

在这里,我们可以看到LabelStyle我们感兴趣的层次结构位置.如果你想快速和肮脏,你可以在你的Button元素中添加它:

Component.onCompleted: children[0].children[1].children[1].children[1].font.pixelSize = 50

但这不是真正可维护的,更可接受的解决方案是遍历我们的子层次结构Button并找到要修改的字体.

我findFont在一个工作示例应用程序中添加了一个函数:

import QtQuick 2.5
import QtQuick.Controls 1.4

ApplicationWindow {
    id: app
    visible: true
    width: 640
    height: 480

    function findFont(object) {
        if (object.font)
            return object.font;
        var font = null;
        for (var index = 0; index < object.children.length && !font; ++index)
            font = findFont(object.children[index]);
        return font;
    }

    Column {
        anchors.centerIn: parent

        Button {
            anchors.horizontalCenter: parent.horizontalCenter
            text: "Button 1"
            width: 300
            height: 100
        }
        Button {
            anchors.horizontalCenter: parent.horizontalCenter
            text: "Button 2"
            width: 300
            height: 100

            Component.onCompleted: {
                findFont(this).pixelSize = 50;
                // On Android and Qt 5.5, this is equivalent :
                //children[0].children[1].children[1].children[1].font.pixelSize = 50;
            }
        }
    }
}