谷歌Spreasheet QUERY功能我可以在ARRAYFORMULA中使用的东西

Question

我有以下查询功能

=QUERY(C:J,"SELECT SUM(J) WHERE C='"&C2&"' AND H<=date'"&TEXT(H2,"yyyy-MM-dd")&"' LABEL SUM(J) ''",0)

C2和H2相对于每一行是唯一的(C2,C3,C4,......和H2,H3,H4 ...)

我需要将它放入ARRAYFORMULA,因此它会在每一行产生一些结果

我已经花了一整天的时间,用SUMIFS检查所有其他解决方案并尝试用MMULT重新编写公式,但没有任何成功.

这是一个简化的例子:

Proj    Date        Hours
APROJ   6/29/2015   81.75
APROJ   6/22/2015   80.75
BPROJ   8/3/2015    689
BPROJ   8/2/2015    656
BPROJ   8/10/2015   688
BPROJ   8/11/2015   729
CPROJ   8/12/2015   1757

我的尝试没有成功:= arrayformula(mmult((A:A = A1:A)*(B:B <= B1:B)*N(C:C),转置(符号(列(C:C))) ))

所需的专栏是:

CHECK
162.5
80.75
1345
656
2033
2762
1757

如果我输入每一行公式:= SUMIFS(C $ 2:C,A $ 2:A,"="&A2,B $ 2:B,"<="&B2)当从第2行手动扩展时它正在工作

提前致谢.

如果您想玩,只需复制到自己:https://docs.google.com/spreadsheets/d/12F4EsHvkiZb5gAPVo_uosd2YpZ1nw9QED_JlSAcVQYU/edit?usp=sharing

Answer 1

答案如下：

=MMULT(TRANSPOSE(ArrayFormula(--($A$2:$A$8=TRANSPOSE(A2:A8))*--($B$2:$B$8<=TRANSPOSE(B2:B8)))),C2:C8)

该公式可以转换为更通用的公式，动态计算范围，即OFFSET(A2,,,COUNTA(A2:A))。

说明

我们使用的mmult函数本身就是一个数组函数。以下是有关 mmult 的帮助中心信息。所以我们要准备两个矩阵。第一个带有条件的矩阵，第二个带有我们已经拥有的数字的矩阵。尝试输入此部分或公式以获取具有条件的矩阵：

=ArrayFormula(--($A$2:$A$8=TRANSPOSE(A2:A8))*--($B$2:$B$8<=TRANSPOSE(B2:B8)))

在这一部分中，我们得到带有 Zoros 和 Ones 的表/矩阵。我更喜欢使用“--”将 Boolaen 转换为整数：相关问题

必须使用其中的转置来使公式展开。这是主要技巧。Arrayformula 不能用于比较两个垂直数组。所以你必须转置其中之一。在您的问题中，我们有两个具有 AND 逻辑的条件：A * B。因此，我们将条件的两部分相乘。但我认为，可以添加两个以上的条件。如果您想使用 OR 条件，则需要将它们添加 A + B。一些示例：

• (A + B) * C -- [A 或 B] AND C
• A + B * C -- A 或 [B 和 C]

结论

这对我来说是一个真正的挑战。顺便说一句，我找到了 5 个不同的公式来计算，但无法将它们转换为 ArrayFormula：

1. 查询，问题中的公式
2. 苏米夫斯
3. 和积
4. 总和（过滤器（...））
5. 总和（如果（A*B，...，0））

查看带有示例的文件