VBScript可以创建文本文件，但是不能删除文件（权限被拒绝）？

Question

我创建一个.vbs文件（可以：创建文本文件->打开notepad.exe->删除上面的文件），如下所示：

' Create a new file
Dim objFS, objFile
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objFile = objFS.CreateTextFile("D:\Folder\Textfile.txt")
objFile.WriteLine ("sample text")

' Run a program and wait
WScript.CreateObject("WScript.Shell").Run "notepad.exe", 1, true

' Delete file
objFS.Deletefile("D:\Folder\Textfile.txt")

但是当我运行它时，关闭记事本窗口后，它显示错误消息：

Line: 10
Char: 1
Error: Permission denied
Code: 800A0046
Source: Microsoft VBScript runtime error

我不知道为什么这个.vbs无法删除文本文件？感谢您的任何帮助！

Answer 1

您必须先删除脚本中的文件句柄，然后再尝试将其删除。

' Create a new file
Dim objFS, objFile
Set objFS = CreateObject("Scripting.FileSystemObject")
Set objFile = objFS.CreateTextFile("D:\Folder\Textfile.txt")

'write to the file
objFile.WriteLine ("sample text")

'close the file
objFile.close
set objFile = Nothing

' open the file in notepad, and wait
WScript.CreateObject("WScript.Shell").Run "notepad.exe D:\Folder\Textfile.txt", 1, true

' Delete file
objFS.Deletefile("D:\Folder\Textfile.txt")

set objFS = Nothing