运行代码时,获取用户定义的类型未定义错误

Question

有谁知道为什么我在Function GetOutlookApp() As Outlook.Application这个代码的底部得到"用户定义的类型未定义"错误？

Sub CreateAppointments()

Dim cell As Excel.Range
Dim rng As Excel.Range
Dim wholeColumn As Excel.Range
Dim startingCell As Excel.Range
Dim oApp As Outlook.Application
Dim tsk As Outlook.TaskItem
Dim wkbk As Excel.Workbook
Dim wksht As Excel.Worksheet
Dim lastRow As Long
Dim arrData As Variant
Dim i As Long

'启动Outlook应用

Set oApp = GetOutlookApp
If oApp Is Nothing Then
  MsgBox "Could not start Outlook.", vbInformation
  Exit Sub
End If

'将工作表范围一次性放入数组中

Set wkbk = ActiveWorkbook
Set wksht = wkbk.ActiveSheet
Set wholeColumn = wksht.Range("B:B")
lastRow = wholeColumn.End(xlDown).Row - 2
Set startingCell = wksht.Range("B2")
Set rng = wksht.Range(startingCell, startingCell.Offset(lastRow, 1))
arrData = Application.Transpose(rng.Value)

'循环遍历数组并为每条记录创建任务

For i = LBound(arrData, 2) To UBound(arrData, 2)
  Set tsk = oApp.CreateItem(olTaskItem)
  With tsk
    .DueDate = arrData(2, i)
    .Subject = arrData(1, i)
    .Save
  End With
Next I

End Sub

Function GetOutlookApp() As Outlook.Application
On Error Resume Next
Set GetOutlookApp = CreateObject("Outlook.Application")

End Function

Answer 1

在从其他程序如何自动化Outlook本文介绍了自动运行Outlook的所有必要的步骤.它指出:

要使用早期绑定,首先需要引用可用的Outlook对象库.若要从Visual Basic(VB)或Visual Basic for Applications执行此操作,请按照下列步骤操作:

1. 在Visual Basic编辑器的"工具"菜单上,单击"引用".
2. 单击以选中Microsoft Outlook 15.0对象库复选框,然后单击确定.