使用列表中的项作为参数

Question

假设我有一个带有以下类型签名的函数:

g :: a -> a -> a -> b

我还有一个as-let的名单xs- 我知道它至少包含三个项目.我想申请g前三项xs.我知道我可以定义如下的组合器:

($$$) :: (a -> a -> a -> b) -> [a] -> b
f $$$ (x:y:z:_) = f x y z

然后我可以使用g $$$ xs.这$$$有点像uncurry,但对于具有相同类型的三个参数和列表而不是元组的函数.

有没有办法使用标准组合器以惯用方式执行此操作？或者更确切地说,在Haskell中最常用的方法是什么？我想尝试pointfree对非缀版本$$$会给我从哪里开始有些想法,但产量与10个憎恶的flipS,极少数headS和tailS和apS和28个括号.

(注意:我知道这首先不是一个非常糟糕的Haskelly事情,但是我遇到过几种似乎是合理解决方案的情况,特别是在使用Parsec时.我当然会接受"不要"T 曾经这样做是真正的代码",如果这是最好的答案,但我更愿意看到一些聪明的把戏涉及((->) r)单子或什么的.)

Answer 1

或者更确切地说,在Haskell中最常用的方法是什么？

成语？如果你真的想要一个可以完成任务的功能,($$$)你拥有的代码可能就像你会得到的那样.

我宁愿看到一些聪明的伎俩

哦,那样的话.

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FunctionalDependencies #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE OverlappingInstances #-}
{-# LANGUAGE UndecidableInstances #-}
class ListApply f a r | f -> a r where
    ($...) :: f -> [a] -> r

instance (TypeCast b r) => ListApply b a r where
    x $... _ = typeCast x

instance (ListApply f a r) => ListApply (a -> f) a r where
    f $... (x:xs) = (f x) $... xs

你去了,一个完全通用的解决方案:给定具有签名的任意arity的功能,根据需要a -> a ... -> b将其应用于列表的任意数量的元素[a].示范:

ones :: [Int]
ones = repeat 1

test1 x = x
test2 x y = x + y
test3 x y z = (x + z) * (y + z)

在GHCi中:

> test1 $... ones
1
> test2 $... ones
2
> test3 $... ones
4

如果那是最好的答案,我当然会接受"不要在实际代码中这样做"

你可能想要这样做.

哦,运行上面的代码需要一些样板:

class TypeCast   a b   | a -> b, b->a   where typeCast   :: a -> b
class TypeCast'  t a b | t a -> b, t b -> a where typeCast'  :: t->a->b
class TypeCast'' t a b | t a -> b, t b -> a where typeCast'' :: t->a->b
instance TypeCast'  () a b => TypeCast a b where typeCast x = typeCast' () x
instance TypeCast'' t a b => TypeCast' t a b where typeCast' = typeCast''
instance TypeCast'' () a a where typeCast'' _ x  = x

这是类型级元编程的瑞士军刀,由Oleg Kiselyov提供.

Answer 2

f $$$ (x:y:z:_) = f x y z

在我看来,这是最习惯和简洁的方式.如果参数的数量不同,您可以使用Template Haskell或迭代地执行 - 定义:

zero = const
next n f (x:xs) = n (f x) xs

那么你的功能是next (next (next zero))),这适用于任何嵌套next.

你也可以将它分解为更原始的组合器:

firstThree (x:y:z:_) = (x,y,z)
uncurry3 f (x,y,z) = f x y z
g f = uncurry3 f . firstThree