使用gnuplot，如何“切出”图形的y轴区域

Question

我正在尝试绘制一个图形，在Y轴上我具有CPU利用率，当前范围是0-100％。我的数据仅包含0-20％和80-100％，而我仅有20-80％的大空白。有什么办法可以“切出”这个空白，以便观众更详细地了解0-20％和80-100％范围内的情况吗？

谢谢。

Answer 1

正如克里斯托夫（Christoph）在评论中所说，这需要使用set multiplot边框和边框等手动完成。例如：

set multiplot
# remove border and ytics from right hand side
set border 7
set ytics nomirror
# set top and bottom margins for both halves of the plot
set tmargin at screen 0.96
set bmargin at screen 0.1
# set left and right margins for left half of the plot
set lmargin at screen 0.1
set rmargin at screen 0.5
# set xrange for left half of the plot
set xrange [0:2*pi]
# set some lines to delimit transition from one half of the plot to next
set arrow from screen 0.50,0.08 to screen 0.52,0.12 nohead
set arrow from screen 0.49,0.08 to screen 0.51,0.12 nohead
set arrow from screen 0.50,0.94 to screen 0.52,0.98 nohead
set arrow from screen 0.49,0.94 to screen 0.51,0.98 nohead
# plot left half
plot sin(x) not
# remove border from left hand side and set ytics on the right
set border 13
unset ytics
set y2tics
set format y2 ""
# set left and right margins for right half of the plot
set lmargin at screen 0.51
set rmargin at screen 0.91
# set xrange for right half of the plot
set xrange [13.5:13.5+2*pi]
# plot
plot sin(x) axes x1y2