在Coq中重写一个匹配项

Question

在Coq中,假设我有一个f在(g x)上匹配定义的fixpoint函数,我想g x = ...在证明中使用form()中的假设.以下是一个最小的工作示例(实际上f,g会更复杂):

Definition g (x:nat) := x.

Fixpoint f (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => f z
      end 
  end.

Lemma test : forall (x : nat), g x = O -> f x = O.
Proof.
  intros.
  unfold f.
  rewrite H. (*fails*)

该消息显示Coq被卡住的地方:

(fix f (x0 : nat) : nat :=
   match g x0 with
   | 0 => 0
   | S _ => match x0 with
            | 0 => 1
            | S z0 => f z0
            end
   end) x = 0

Error: Found no subterm matching "g x" in the current goal.

但是,这些命令unfold f. rewrite H.不起作用.

我如何获得Coq unfold f然后使用H？

Answer 1

Parameter g: nat -> nat.

(* You could restructure f in one of two ways: *)

(* 1. Use a helper then prove an unrolling lemma: *)

Definition fhelp fhat (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => fhat z
      end 
  end.

Fixpoint f (x:nat) := fhelp f x.

Lemma funroll : forall x, f x = fhelp f x.
destruct x; simpl; reflexivity.
Qed.

Lemma test : forall (x : nat), g x = O -> f x = O.
Proof.
  intros.
  rewrite funroll.
  unfold fhelp.
  rewrite H.
  reflexivity.
Qed.

(* 2. Use Coq's "Function": *)

Function f2 (x:nat) := 
  match g x with
    | O => O
    | S y => match x with 
      | O => S O
      | S z => f2 z
      end 
  end.

Check f2_equation.

Lemma test2 : forall (x : nat), g x = O -> f2 x = O.
Proof.
  intros.
  rewrite f2_equation.
  rewrite H.
  reflexivity.
Qed.