如何重用模板匹配找到的ID？

Question

如何在另一个模板中使用搜索结果？假设这个:

 <parent>
    <test>
        <bla Id="1">
            <mychild attr="x" />
        </bla>
        <bla Id="2">
            <mychild attr="y" />
        </bla>
        <bla Id="3">
            <mychild attr="z" />
        </bla>
    </test>

    <test2>
        <bla2 Id="1" />
        <bla2 Id="2" />
        <bla2 Id="3" />
    </test2>
</parent>

我想首先找出哪个bla有一个attr ="x"的孩子,保存bla的Id然后删除每个<bla2>拥有该ID以及<bla>它自己的ID .到目前为止我有这个:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:wix="http://schemas.microsoft.com/wix/2006/wi">
<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*" />

<xsl:template match="@*|node()">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()"/>
 </xsl:copy>
</xsl:template>


<xsl:template match="parent/test/bla">
  <xsl:choose>
        <xsl:when test="mychild[@attr='x']">
            <!-- apparently I cannot reuse this.. -->
            <xsl:variable name="idToDelete"><xsl:value-of select="@Id"/></xsl:variable>
        </xsl:when>
        <xsl:otherwise>
          <xsl:copy-of select="."/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

它适用于删除第一个<bla>,但现在我坚持如何重用Id来删除bla2具有该ID 的项目在另一个模板匹配/搜索.我尝试了xsl:variable(它们显然超出范围..)我尝试使用with-param调用模板...由于某种原因,在第一场比赛中没有删除项目而第二个模板也没有用.如何以XSLT™方式解决此问题？

Answer 1

我建议从相反的方向看它:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="bla" match="bla" use="@Id" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="bla[mychild/@attr='x']"/>
<xsl:template match="bla2[key('bla', @Id)/mychild/@attr='x']" />

</xsl:stylesheet>

IOW,删除任何bla具有mychild使用attr ="X",然后删除任何bla2具有bla具有相同ID,其mychild具有ATTR ="X".

编辑:

如果您愿意,可以通过告知密钥仅索引感兴趣的节点来提高效率:

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:key name="deleted-bla" match="bla[mychild/@attr='x']" use="@Id" />

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="bla[key('deleted-bla', @Id)]"/>
<xsl:template match="bla2[key('deleted-bla', @Id)]" />

</xsl:stylesheet>