AS3 Flex 中的排序对象/地图？

Question

是否可以在 Actionscript 3 Flex 中对对象进行排序或对对象进行某种排序？我有一个像这样创建的对象：

private var data:Object = new Object();

然后我继续将一些键和值放入其中：

this.data.someKeyOne = 0;
this.data.someKeyTwo = 1337;
this.data.someKeyThree = 123;

之后我循环遍历对象：

for (var dataPart:String in this.data) {
    trace("Key: " + dataPart = " Value:" + this.data["dataPart"]);
}

但我的问题是数据不会按照我初始化它们的顺序显示。这是令人沮丧的，因为它需要按照初始化的顺序显示。

Answer 1

正如@helloflash 在他关于循环对象的回答中所说的，根据Adobe 的定义associative array（它是 Object 类的一个实例）：

关联数组，有时称为散列或映射，使用键而不是数字索引来组织存储的值。关联数组中的每个键都是用于访问存储值的唯一字符串。关联数组是 Object 类的一个实例，这意味着每个键对应一个属性名称。关联数组是键值对的无序集合。您的代码不应期望关联数组的键按特定顺序排列。

你得到的行为是正常的，在你的情况下你不能得到有序的键（使用这样的对象）。

如果您不需要密钥，您可以按照@helloflash 在他的回答中所说的那样使用简单的数组或向量。否则，您可以使用对象数组，如下所示：

var obj:Object, i:int, s:String;

var data_array:Array = [
        {key: 'someKeyOne', value: 0},
        {key: 'someKeyTwo', value: 1337},
        {key: 'someKeyThree', value: 123}
    ]
for(i = 0; i < data_array.length; i++){
    obj = data_array[i];
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}
for (s in data_array) {
    obj = data_array[s];
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}
for each (obj in data_array){
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}

// all these 3 loops give :     
//  Key : someKeyOne, Value = 0
//  Key : someKeyTwo, Value = 1337
//  Key : someKeyThree, Value = 123

或者您可以使用 Object 然后将其排序为一个数组，如下所示：

var data_object:Object = new Object();
    data_object.someKeyOne   = {index:0, value: 0};
    data_object.someKeyTwo   = {index:1, value: 1337};
    data_object.someKeyThree = {index:2, value: 123};

var tmp_array:Array = sort_obj(data_object);

for(i = 0; i < tmp_array.length; i++){
    obj = tmp_array[i];
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}
for (obj in tmp_array) {
    obj = tmp_array[obj];
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}
for each (obj in tmp_array){
    trace('Key : ' + obj.key + ', Value = ' + obj.value);
}

function sort_obj(obj:Object):Array {
    var a:Array = [];
    for (var key:String in obj) {
        a.push({key: key, index: obj[key].index, value: obj[key].value});
    }
    a.sortOn('index', Array.NUMERIC);
    return a;
}

// all these 3 loops give :     
//  Key : someKeyOne, Value = 0
//  Key : someKeyTwo, Value = 1337
//  Key : someKeyThree, Value = 123

希望所有能帮到你。