如何通过更改inno安装脚本在欢迎页面的空白处添加新文本？

Question

在 inno setup 的欢迎屏幕上，我想在“单击下一步继续，或取消退出安装”行下方的空白区域中添加 NEW_TEXT

但只能通过覆盖该部分的值在“单击下一步继续，或取消退出安装”行上方添加 NEW_TEXT [Messages]：

[Messages]
WelcomeLabel2=This will install [name/ver] on your computer.%n%nIt is recommended that you close all other applications before continuing %n%n NEW_TEXT.

截屏：

我可以通过编辑 inno setup 脚本在上面指定的空白区域添加文本吗？

Answer 1

WelcomeLabel2您可以减小拉伸到页面底部的高度并创建自己的静态文本控件，例如：

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[CustomMessages]
WelcomeLabel3=Hello world!

[Code]
var
  WelcomeLabel3: TNewStaticText;

procedure InitializeWizard;
begin
  // you can set e.g. the fixed height to the original WelcomeLabel2, or
  // you can set the WelcomeLabel2 to auto-size to the text content it's
  // showing; to set the fixed height, use the following line:
  // WizardForm.WelcomeLabel2.Height := 97;
  WizardForm.WelcomeLabel2.AutoSize := True;

  // now you got some space on the welcome page, so let's fill it up with
  // your own label called WelcomeLabel3
  WelcomeLabel3 := TNewStaticText.Create(WizardForm);
  WelcomeLabel3.Parent := WizardForm.WelcomePage;
  WelcomeLabel3.AutoSize := False;
  WelcomeLabel3.Left := WizardForm.WelcomeLabel2.Left;
  WelcomeLabel3.Top := WizardForm.WelcomeLabel2.Top +
    WizardForm.WelcomeLabel2.Height;
  WelcomeLabel3.Width := WizardForm.WelcomeLabel2.Width;
  WelcomeLabel3.Height := WizardForm.WelcomePage.Height - WelcomeLabel3.Top;
  WelcomeLabel3.Font.Assign(WizardForm.WelcomeLabel2.Font);
  WelcomeLabel3.Caption := CustomMessage('WelcomeLabel3');

  // these three lines can help you to see the label composition since it
  // colorize them; remove this when you'll be done
  WizardForm.WelcomeLabel1.Color := clYellow;
  WizardForm.WelcomeLabel2.Color := $000080FF;
  WelcomeLabel3.Color := clRed;
end;