管道中的空间泄漏与RWST

Question

以下程序的存储器分析表明,noleak函数在常量存储器中运行,而泄漏函数以线性方式泄漏存储器.dflemstr表明这可能是由于RWST导致无限的分配链.是这种情况还有其他解决方案吗？我实际上不需要Writer monad.

环境:

ARCH 64位GHC 7.8.3

ghc Pipe.hs -o Pipe -prof

import Control.Concurrent (threadDelay)
import Control.Monad (forever)

import Pipes
import Control.Monad.Trans.RWS.Strict

main = leak

effectLeak :: Effect (RWST () () () IO) ()
effectLeak =
  (forever $ do
      liftIO . threadDelay $ 10000 * 1
      yield "Space") >->
  (forever $ do
      text <- await
      yield $ text ++ (" leak" :: String)) >->
  (forever $ do
      text <- await
      liftIO . print $ text
  )

effectNoleak :: Effect IO ()
effectNoleak =
  (forever $ do
      lift . threadDelay $ 10000 * 1
      yield "Space") >->
  (forever $ do
      text <- await
      yield $ text ++ (" leak" :: String)) >->
  (forever $ do
      text <- await
      lift . print $ text
  )

leak = (\e -> runRWST e () ()) . runEffect $ effectLeak

noleak = runEffect $ effectNoleak

Answer 1

泽塔是正确的,因为空间泄漏WriterT. WriterT并且RWST("严格"和"懒惰"版本)无论你使用什么样的monoid,总是会泄漏空间.

我在这里写了一个更长的解释,但这里是摘要:不泄漏空间的唯一方法是模拟使用严格模拟WriterT的StateTmonad ,如下所示:tellput

newtype WriterT w m a = WriterT { unWriterT :: w -> m (a, w) }

instance (Monad m, Monoid w) => Monad (WriterT w m) where
    return a = WriterT $ \w -> return (a, w)
    m >>= f  = WriterT $ \w -> do
        (a, w') <- unWriterT m w
        unWriterT (f a) w'

runWriterT :: (Monoid w) => WriterT w m a -> m (a, w)
runWriterT m = unWriterT m mempty

tell :: (Monad m, Monoid w) => w -> WriterT w m ()
tell w = WriterT $ \w' ->
    let wt = w `mappend` w'
     in wt `seq` return ((), wt)

这基本上相当于:

type WriterT = StateT

runWriterT m = runStateT m mempty

tell w = do
    w' <- get
    put $! mappend w w'

Answer 2

看来这Writer部分RWST实际上是罪魁祸首:

instance (Monoid w, Monad m) => Monad (RWST r w s m) where
    return a = RWST $ \ _ s -> return (a, s, mempty)
    m >>= k  = RWST $ \ r s -> do
        (a, s', w)  <- runRWST m r s
        (b, s'',w') <- runRWST (k a) r s'
        return (b, s'', w `mappend` w') -- mappend
    fail msg = RWST $ \ _ _ -> fail msg

如你所见,作者使用普通的mappend.由于(,,)它的论点并不严格,所以w `mappend` w'构建了一系列的thunk,即使是艰难的Monoid实例() 也是相当微不足道的:

instance Monoid () where
        -- Should it be strict?
        mempty        = ()
        _ `mappend` _ = ()
        mconcat _     = ()

为了解决这个问题,你需要w `mappend` w'在元组中添加严格性:

        let wt = w `mappend` w'
        wt `seq` return (b, s'', wt) 

但是,如果你不需要Writer,你可以简单地使用ReaderT r (StateT st m):

import Control.Monad.Trans.Reader
import Control.Monad.Trans.State.Strict

type RST r st m = ReaderT r (StateT st m)

runRST :: Monad m => RST r st m a -> r -> st -> m (a,st)
runRST rst r st = flip runStateT st . flip runReaderT r $ rst

但是,鉴于这会强制您对lift正确的monad进行计算,您可能希望使用该mtl包.代码将保持不变,但在这种情况下导入将是以下内容

import Control.Monad.Reader
import Control.Monad.State.Strict