Qt/QMake iOS设置目标,设备,其他XCode设置

Question

Qt for iOS在您执行构建时创建一个XCode项目.

如何从Qt指定XCode项目设置来设置"目标"(最低iOS版本)和"设备"(通用/ iPhone/iPad),如此项目打开时在XCode的"常规"选项卡上找到？

Answer 1

我无法在任何地方找到这个记录,但我明白了.

在你的qmake(pro或pri文件)中添加以下行:

# Set "Target"
QMAKE_IOS_DEPLOYMENT_TARGET = 5.0

# Set "Devices" (2=iPad Only)
QMAKE_IOS_TARGETED_DEVICE_FAMILY = 2

设备注意事项:1 = iPhone,2 = iPad,1,2 =通用.

如果您需要在此处更改其他XCode项目设置,您可以:

在Qt for iOS中构建之后,查看"编译输出"选项卡.您将找到"export VARIBALE = some_value"条目的列表.要更改其中一个XCode构建设置,只需在qmake中使用QMAKE_IOS_VARIABLE_NAME = my_value即可.

有关这些环境变量的更多信息,请查看:Xcode构建设置参考

- 更新 -

关于最后一部分,我错了.你不能像这样设置所有的XCode变量.但是,如果输出QMAKESPEC,您将获得可以找到qmake.conf文件的路径,该文件将显示其中一些未记录的变量.在你的pro/pri中这样做:

  message( $$QMAKESPEC )

在构建项目时,该路径将显示在Qt控制台"常规"选项卡中.

这是我现在使用的扩展版本,其中包含一些用于设置构建体系结构的逻辑:

greaterThan( QT_MAJOR_VERSION, 5 ){
   DEFINES += QT_VER_5_4_OR_NEWER
}
else:equals( QT_MAJOR_VERSION, 5 ) &&
    greaterThan( QT_MINOR_VERSION, 3 ){
    DEFINES += QT_VER_5_4_OR_NEWER
}

contains(DEFINES, QT_VER_5_4_OR_NEWER){
    DEFINES += SUPPORT_64_BIT_IOS
    message( "SUPPORT_64_BIT_IOS" )
}

contains(DEFINES, SUPPORT_64_BIT_IOS) {
    iosArchitectures="armv7 arm64"
    iosTarget=5.1.1
}
else{
    iosArchitectures=armv7
    iosTarget=5.0
}

# Set "Architectures"
QMAKE_IOS_DEVICE_ARCHS = $$iosArchitectures

# Set "Target"
QMAKE_IOS_DEPLOYMENT_TARGET = $$iosTarget

# Set "Devices" (1=iPhone, 2=iPad, 1,2=Universal)
QMAKE_IOS_TARGETED_DEVICE_FAMILY = 2