如何在Inno Setup中拆分字符串

Question

如何在Inno Setup中拆分字符串？
Inno Setup中是否有任何特殊功能来分割字符串？

我想从字符串中获取以下内容'11.2.0.16':

tokens: array of string = ('11', '0', '2', '16');

提前致谢!

Answer 1

我今天一直在寻找同样的事情......

这个在Inno Setup Scripts上运行得很好.在脚本/函数之前将此摘录粘贴到脚本中,这将调用此"拆分"过程.

如果你愿意,你也可以将它修改为一个函数...

procedure Explode(var Dest: TArrayOfString; Text: String; Separator: String);
var
  i, p: Integer;
begin
  i := 0;
  repeat
    SetArrayLength(Dest, i+1);
    p := Pos(Separator,Text);
    if p > 0 then begin
      Dest[i] := Copy(Text, 1, p-1);
      Text := Copy(Text, p + Length(Separator), Length(Text));
      i := i + 1;
    end else begin
      Dest[i] := Text;
      Text := '';
    end;
  until Length(Text)=0;
end;

procedure Whatever();
var 
  str: String;
  strArray: TArrayOfString;
  i: Integer;
begin
  Explode(strArray,str,'.');
  for i:=0 to GetArrayLength(strArray)-1 do begin
    //do something
  end;
end;

取自这里

Answer 2

对于任何喜欢函数格式的人,我已经从@ cezar-lamann修改了上述内容:

function StrSplit(Text: String; Separator: String): TArrayOfString;
var
  i, p: Integer;
  Dest: TArrayOfString; 
begin
  i := 0;
  repeat
    SetArrayLength(Dest, i+1);
    p := Pos(Separator,Text);
    if p > 0 then begin
      Dest[i] := Copy(Text, 1, p-1);
      Text := Copy(Text, p + Length(Separator), Length(Text));
      i := i + 1;
    end else begin
      Dest[i] := Text;
      Text := '';
    end;
  until Length(Text)=0;
  Result := Dest
end;