如何在Perl中迭代哈希(哈希)？

Question

我有哈希,其中键的值是其他哈希.

例: {'key' => {'key2' => {'key3' => 'value'}}}

我怎样才能遍历这个结构？

Answer 1

这个答案建立在Dave Hinton背后的思想基础之上 - 即编写一个通用子程序来构建哈希结构.这样的散列遍历器获取代码引用,并简单地为散列中的每个叶节点调用该代码.

使用这种方法,可以使用相同的散列行者来做很多事情,具体取决于我们给它的回调.为了获得更大的灵活性,您需要传递两个回调 - 一个是在值是哈希引用时调用,另一个是在普通标量值时调用.Marc Jason Dominus的优秀着作" 高阶Perl "更深入地探讨了这样的策略.

use strict;
use warnings;

sub hash_walk {
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
    }
}

my %data = (
    a => {
        ab => 1,
        ac => 2,
        ad => {
            ada => 3,
            adb => 4,
            adc => {
                adca => 5,
                adcb => 6,
            },
        },
    },
    b => 7,
    c => {
        ca => 8,
        cb => {
            cba => 9,
            cbb => 10,
        },
    },
);

sub print_keys_and_value {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $v, "@$key_list";
}

hash_walk(\%data, [], \&print_keys_and_value);

Answer 2

这是你想要的吗？(另)

sub for_hash {
    my ($hash, $fn) = @_;
    while (my ($key, $value) = each %$hash) {
        if ('HASH' eq ref $value) {
            for_hash $value, $fn;
        }
        else {
            $fn->($value);
        }
    }
}

my $example = {'key' => {'key2' => {'key3' => 'value'}}};
for_hash $example, sub {
    my ($value) = @_;
    # Do something with $value...
};

Answer 3

这篇文章可能有用.

foreach my $key (keys %hash) {
    foreach my $key2 (keys %{ $hash{$key} }) {
        foreach my $key3 (keys %{ $hash{$key}{$key2} }) {
            $value = $hash{$key}{$key2}->{$key3};
            # .
            # .
            # Do something with $value
            # .
            # .
            # .
        }
    }
}

Answer 4

前面的答案显示了如何推出自己的解决方案,这至少可以做一次,这样您就可以理解perl引用和数据结构的工作方式.如果你还没有,你绝对应该通过perldoc perldsc和perldoc perlref读取.

但是,您不需要编写自己的解决方案--CPAN上已经有一个模块可以为您迭代任意复杂的数据结构:Data :: Visitor.

Answer 5

另外,请通读 perldoc perldsc.您可以深入了解哈希