使用Perl中的正则表达式列出来自另一个Perl脚本的变量

Question

我对如何从Perl文件中获取所有标量和数组的想法遵循以下方针:

open (InFile, "SomeScript.pl");
@InArray = <InFile>;
@OutArray = {};
close (InFile);
$ArrayCount = @InArray;
open (OutFile, ">outfile.txt");
for ($x=0; $x<=$ArrayCount; $x++){
$Testline = @InArray[$x];

if($Testline =~ m/((@|\$)[A-Z]+)/i){
    $Outline = "$1\n";  
    push @OutArray, $Outline;
}
}
print OutFile @OutArray;
close(OutFile);

......而且效果相当好.问题是如果一行上出现多个变量,它只会获取第一个变量.一个例子可能是:

$FirstVar = $SecondVar + $ThirdVar;

该脚本只会抓取$FirstVar并输出到文件.这可能仍然有效,因为$SecondVar并且$ThirdVar必须在前一行有任何意义之前在其他地方初始化.我想规则的例外是一条线,其中多个变量同时被初始化.

真正的Perl代码中的示例是否会破坏此脚本？另外,如何从同一行中获取符合我的正则表达式条件的多个项目？

Answer 1

不要那样做

你无法用正则表达式解析Perl,所以我甚至都不会尝试.
如果不实际运行它,你甚至无法正确解析它,但你可以接近PPI.

perl-variables.pl

#! /usr/bin/env perl
use strict;
use warnings;
use 5.10.1;

use PPI;
use PPI::Find;

my($filename) = (@ARGV, $0); # checks itself by default

my $Doc = PPI::Document->new($filename);
my $Find = PPI::Find->new( sub{
  return 0 unless $_[0]->isa('PPI::Token::Symbol');
  return 1;
});

$Find->start($Doc);
while( my $symbol = $Find->match ){
  my $raw = $symbol->content;
  my $var = $symbol->symbol;
  if( $raw eq $var ){
    say $var;
  } else {
    say "$var\t($raw)";
  }
}
print "\n";

my @found = $Find->in($Doc);
my %found;
$found{$_}++ for @found;

say for sort keys %found;

针对自身运行,产生:

$filename
@ARGV
$0
$Doc
$filename
$Find
@_  ($_)
$Find
$Doc
$symbol
$Find
$raw
$symbol
$var
$symbol
$raw
$var
$var
@found
$Find
$Doc
%found
%found  ($found)
$_
@found
%found

$0
$Doc
$Find
$_
$filename
$found
$raw
$symbol
$var
%found
@ARGV
@found