xsl 1.0上的日期操作

Question

我需要在变量中定义的给定日期之前和之后3天获取,并将它们中的每一个存储在xsl 1.0中的新单个变量中.我不能使用任何扩展或第三方工具.

通过论坛中的答案,我发现:在XSLT 1.0中扩展日期时间范围以 解决类似的问题,但我不完全理解它是否以及如何适用于我的代码.

Mi日期变量采用标准的dateTime格式,如下所示:

<xsl:variable name="Date" select="2014-05-13T00:00:00"/>

我需要输出类似于此的html:

<table>
  <tr>
    <td>
   2014-05-10
    <td>
  </tr>
  <!---some rows with pricing information -->
</table>
<table>
  <tr>
    <td>
   2014-05-11
    <td>
  </tr>
  <!---some rows with pricing information -->
</table>
<table>
  <tr>
    <td>
   2014-05-12
    <td>
  </tr>
  <!---some rows with pricing information -->
</table>
<!-- etc -->

在具有定价信息的行中,我将必须使用每个单独的日期来执行其他操作,因此每天必须存储在变量中以供进一步使用.

有没有办法实现这一点,只使用xslt 1.0？

提前致谢.

Answer 1

在纯XSLT 1.0中添加/减去日期的天数:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="givenDate" select="'2014-05-13T00:00:00'"/>
<xsl:param name="daysDiff" select="-3"/>

<xsl:variable name="JDN">
    <xsl:call-template name="JDN">
        <xsl:with-param name="date" select="$givenDate" />
    </xsl:call-template>
</xsl:variable>

<xsl:variable name="newDate">
    <xsl:call-template name="GD">
        <xsl:with-param name="JDN" select="$JDN + $daysDiff" />
    </xsl:call-template>
</xsl:variable>


<xsl:template match="/">
    <output>
        <GivenDate><xsl:value-of select="$givenDate"/></GivenDate>
        <NewDate><xsl:value-of select="$newDate"/></NewDate>
    </output>
</xsl:template> 


<xsl:template name="JDN">
    <xsl:param name="date"/>
    <xsl:param name="year" select="substring($date, 1, 4)"/>
    <xsl:param name="month" select="substring($date, 6, 2)"/>
    <xsl:param name="day" select="substring($date, 9, 2)"/>
    <xsl:param name="a" select="floor((14 - $month) div 12)"/>
    <xsl:param name="y" select="$year + 4800 - $a"/>
    <xsl:param name="m" select="$month + 12*$a - 3"/>
    <xsl:value-of select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />
</xsl:template> 

<xsl:template name="GD">
    <xsl:param name="JDN"/>
    <xsl:param name="f" select="$JDN + 1401 + floor((floor((4 * $JDN + 274277) div 146097) * 3) div 4) - 38"/>
    <xsl:param name="e" select="4*$f + 3"/>
    <xsl:param name="g" select="floor(($e mod 1461) div 4)"/>
    <xsl:param name="h" select="5*$g + 2"/>
    <xsl:param name="D" select="floor(($h mod 153) div 5 ) + 1"/>
    <xsl:param name="M" select="(floor($h div 153) + 2) mod 12 + 1"/>
    <xsl:param name="Y" select="floor($e div 1461) - 4716 + floor((14 - $M) div 12)"/>
    <xsl:param name="MM" select="substring(100 + $M, 2)"/>
    <xsl:param name="DD" select="substring(100 + $D, 2)"/>
    <xsl:value-of select="concat($Y, '-', $MM, '-', $DD)" />
</xsl:template>     

</xsl:stylesheet>

结果:

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <GivenDate>2014-05-13T00:00:00</GivenDate>
   <NewDate>2014-05-10</NewDate>
</output>

-
请注意,givenDate的参数值是一个字符串,因此必须用单引号括起来.