在Haskell中动态构建列表理解

Question

我很好奇是否有可能在Haskell中动态构建列表理解.

举个例子,如果我有以下内容:

all_pows (a,a') (b,b') = [ a^y * b^z | y <- take a' [0..], z <- take b' [0..] ]

我得到了我想要的东西

*Main> List.sort $ all_pows (2,3) (5,3)
[1,2,4,5,10,20,25,50,100]

但是,我真正喜欢的是拥有类似的东西

all_pows [(Int,Int)] -> [Integer]

这样我就可以N在不构建N版本的情况下支持参数对all_pows.我仍然是Haskell的新手,所以我可能忽略了一些显而易见的事情.这甚至可能吗？

Answer 1

列表monad的魔力:

ghci> let powers (a, b) = [a ^ n | n <- [0 .. b-1]]
ghci> powers (2, 3)
[1,2,4]
ghci> map powers [(2, 3), (5, 3)]
[[1,2,4],[1,5,25]]
ghci> sequence it
[[1,1],[1,5],[1,25],[2,1],[2,5],[2,25],[4,1],[4,5],[4,25]]
ghci> mapM powers [(2, 3), (5, 3)]
[[1,1],[1,5],[1,25],[2,1],[2,5],[2,25],[4,1],[4,5],[4,25]]
ghci> map product it
[1,5,25,2,10,50,4,20,100]
ghci> let allPowers list = map product $ mapM powers list
ghci> allPowers [(2, 3), (5, 3)]
[1,5,25,2,10,50,4,20,100]

这可能需要更多解释.

你可以写自己的

cartesianProduct :: [[a]] -> [[a]]
cartesianProduct [] = [[]]
cartesianProduct (list:lists)
  = [ (x:xs) | x <- list, xs <- cartesianProduct lists ]

这样cartesianProduct [[1],[2,3],[4,5,6]]⇒ [[1,2,4],[1,2,5],[1,2,6],[1,3,4],[1,3,5],[1,3,6]].

然而,理解和单子故意相似.标准的Prelude有sequence :: Monad m => [m a] -> m [a],当m列表monad时[],它实际上完全按照我们上面写的那样做.

作为另一种捷径,mapM :: Monad m => (a -> m b) -> [a] -> m [b]仅仅是sequence和的组合map.

对于每个基数的不同幂的每个内部列表,您希望将它们乘以一个数字.你可以递归地写这个

product list = product' 1 list
  where product' accum [] = accum
        product' accum (x:xs)
          = let accum' = accum * x
             in accum' `seq` product' accum' xs

或使用折叠

import Data.List
product list = foldl' (*) 1 list

但实际上,product :: Num a => [a] -> a已经定义了!我喜欢这种语言☺☺☺