如何获取当前活动应用程序窗口的路径？

Question

我想获取当前活动窗口的可执行文件的路径。

我试过：

var
  WindowModuleFileName : array[0..100] of Char;  
  sourceWindow: Hwnd;      
begin
  sourceWindow := GetActiveWindow;
  GetWindowModuleFileName(sourceWindow, PChar(WindowModuleFileName), sizeof(WindowModuleFileName));    
  ShowMessage(WindowModuleFileName);    
end;

但只有当我的应用程序窗口处于活动状态时它才返回正确的答案。我究竟做错了什么？

Answer 1

您不能用于GetWindowModuleFileName查找除您自己的进程之外的其他进程的文件，如GetModuleFileName MSDN中所述：

检索包含指定模块的文件的完全限定路径。该模块必须已由当前进程加载。

要查找由另一个进程加载的模块的文件，请使用 GetModuleFileNameEx 函数。

因此，您必须GetModuleFileNameEx与GetWindowThreadProcessId/结合使用GetForegroundWindow。这将返回您需要的内容：

uses
  Winapi.Windows, Winapi.PsAPI, System.SysUtils;

function GetCurrentActiveProcessPath: String;
var
  pid     : DWORD;
  hProcess: THandle;
  path    : array[0..4095] of Char;
begin
  GetWindowThreadProcessId(GetForegroundWindow, pid);

  hProcess := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, FALSE, pid);
  if hProcess <> 0 then
    try
      if GetModuleFileNameEx(hProcess, 0, @path[0], Length(path)) = 0 then
        RaiseLastOSError;

      result := path;
    finally
      CloseHandle(hProcess);
    end
  else
    RaiseLastOSError;
end;