设置带有返回值的 eventHandler

Question

我需要调用事件处理程序来告诉用户选择TCard或TLabel ，然后返回该值作为参数。

我有两个单位GAME，SS_SPELL

这就是 SS_SPEll 中的代码的工作原理。

// TSPELL
// ======
// The chronology is:
// 1.  At appropriate points in the game (such as before turn, after cast etc aka trigger points)
//     the game calls the SpellMeister's RunSpells method.
// 2.  RunSpells checks the database for spells matching the card that
//     initiated the spell action, and the trigger point at which it did so.
//     For each one that it finds it will create an appropriate object, which
//     could be a TSpell descendent or a TSpellAdjuster descendent.
//     For each TSpell it finds it fires off an onFindSpell event.
//     See below for details of how TSpellAdjusters are handled.
// 3.  The handler for the onFindSpell events can (should) call the spells'
//     AimAt method for each potential target. A potential target is a card
//     or a player.
// 4.  A spell's AimAt method checks if the potential target is a legitimate
//     target for that spell and if so it calls its ApplySpellTo method to
//     actually do the dirty deed.

所以我需要的是，一旦 RunSpells 获取数据库信息，它将检查是否 need2ndtarget := 1 ，如果是这样，那么我知道我需要这个咒语的第二个目标。

这是创建TSpellBase类的地方。TSpell为了尝试创建此事件，我FOnSeek2ndTarget 在私有部分以及FNeed2Target受保护和公共财产中添加了内容OnSeek2ndTarget。您还会看到TTargetEvt，当前它的设置是接收 TCARD，但我需要它来接收 TCard 或 TLAbel，不知道如何执行此操作。

 TTargetEvt = procedure (Card : TCard) of Object;  


 TSpellBase = class
  private
    FOnManaChange: TManaEvt;
    FOnSeek2ndTarget: TTargetEvt;

  protected
    FCardType            : TCardType;
    FOriginator          : TCard;
    FNeed2Target         : integer;

    function  LegitimateTarget    (Candidate : TObject) : boolean; virtual;
  public
    constructor Create; virtual;

    property CardType    : TCardType     read FCardType     write FCardType;    // ctLava, ctNature, ctWizard, etc etc
    property Originator  : TCard         read FOriginator   write FOriginator;

    property Need2Target : integer       read FNeed2Target  write FNeed2Target;
    property OnManaChange  : TManaEvt  read FOnManaChange  write FOnManaChange;
    property OnSeek2ndTarget : TTargetEvt read FonSeek2ndTarget write FOnSeek2ndTarget;
  end;

现在在 TSpell 中，我认为我不需要在这里进行任何更改，但它需要用于pellmiester.runspell 过程

TSpell = class(TSpellBase)
  private
  protected
    FCategory    : TCategory;
    FLifeToAdd   : Byte;
    FMaxRandom   : Byte;
    FReplaceDmg  : Byte;
    FReplacement : string;
    FStatTarget  : Byte;
    FTrigger     : TTrigger;
    procedure ApplySpellTo(Target : TObject); virtual; abstract; // Apply the spell to the target
  public
    procedure AimAt(Candidate: TObject); virtual;

    property Category    : TCategory     read FCategory     write FCategory;
    property LifeToAdd   : Byte          read FLifeToAdd    write FLifeToAdd;
    property MaxRandom   : Byte          read FMaxRandom    write FMaxRandom;
    property ReplaceDmg  : Byte          read FReplaceDmg   write FReplaceDmg;
    property Replacement : string        read FReplacement  write FReplacement;
    property StatTarget  : Byte          read FStatTarget   write FStatTarget;
    property Trigger     : TTrigger      read FTrigger      write FTrigger;
  end;

在这里我添加了FOnSeek2ndTarget私人部分。和属性所以现在当施放咒语时它会到达这里并调用 runspells。

 TSpellMeister = class
  private
    FonFindSpell   : TRcvSpell;
    FOnManaChange  : TManaEvt;
    FOnSeek2ndTarget  : TTargetEvt;
//    FonNewAdjuster : TRcvSpell;
  protected
    FAdjusters : TAdjusters;
    FQuery : TADOQuery;

  public
    constructor Create(DBCon: TADOConnection);
    destructor Destroy; override;

    function IfNull( const Value, Default : OleVariant ) : OleVariant;
    procedure Adjust(Attacker : TCard; Victim : TObject; var TheDamage : integer); overload;
    procedure Adjust(Attacker : TCard;                   var TheCost   : integer); overload;
    procedure RunSpells(Card : TCard; Trigger : TTrigger);

    property onFindSpell   : TRcvSpell read FonFindSpell   write FonFindSpell;
    property OnManaChange  : TManaEvt  read FOnManaChange  write FOnManaChange;
    property OnSeek2ndTarget: TTargetEvt read FOnSeek2ndTarget write FOnSeek2ndTarget;
//    property onNewAdjuster : TRcvSpell read FonNewAdjuster write FonNewAdjuster;
  end;

这就是问题所在，我添加了foundspell.Need2ndTarget从数据库获取数据，如果它是 1，那么它需要用户为咒语选择另一个目标。目前我添加了

如果 FoundSpell.Need2Target = 1 那么 FOnSeek2ndTarget(Card);

但我确信这是不正确的......

 //**************************************************************************
procedure TSpellMeister.RunSpells(Card: TCard; Trigger: TTrigger);
//**************************************************************************
var
  OneSpell : TSpellBase;
  FoundSpell : TSpell;  // Just so only have to cast once
begin
  assert(assigned(FonFindSpell),'TSpellMeister.RunSpells : No onFindSpell event handler!');
  // Search the database
  FQuery.Active := FALSE;
  FQuery.Parameters.ParamByName(SQL_PARAM_SPELL_ORIGINATOR).Value := Card.CName;
  FQuery.Parameters.ParamByName(SQL_PARAM_SPELL_TRIGGER   ).Value := Trigger;
  FQuery.Active := TRUE;

  // Iterate through the spell records. For each one, create a category-specific
  // TSpell descendant and fire off an onFindSpell event.

  if FQuery.RecordCount > 0 then
  begin
    FQuery.Recordset.MoveFirst;
    while not FQuery.Recordset.EOF do
    begin
      case TCategory(FQuery.Recordset.Fields[DB_FLD_CATEGORY].Value) of
        caAboveLife               : OneSpell := TSpellAboveLife.Create;
        caDamage                  : OneSpell := TSpellDamage.Create;
        caDamagePlus              : OneSpell := TSpellDamagePlus.Create;
        caDamagePlusPercent       : OneSpell := TSpellDamagePlusPercent.Create;
        caDamagePercentIncrease   : OneSpell := TSpellDamagePercentIncrease.Create;
        caDamagePercentDecrease   : OneSpell := TSpellDamagePercentDecrease.Create;
        caDamageSpells            : OneSpell := TSpellDamageSpells.Create;
        caDestroy                 : OneSpell := TSpellDestroy.Create;
        .....
        else                        raise ERangeError.CreateFmt(ERROR_INVALID_DB_NUMBER,[DB_FLD_CATEGORY,FQuery.Recordset.Fields[DB_FLD_CATEGORY].Value]);
      end;
      try
        if assigned(OneSpell) then
        begin
          OneSpell.CardType     := TCardType  (IfNull( FQuery.Recordset.Fields[ DB_FLD_CARD_TYPE   ].Value,0) );
          OneSpell.Originator   := Card;
          OneSpell.OnManaChange := Self.OnManaChange;
          OneSpell.OnSeek2ndTarget := self.OnSeek2ndTarget;
          assert(OneSpell.Originator.COwner is TPlayer,'TSpellMeister.RunSpells : OneSpell.Originator.COwner not a player: ' + OneSpell.Originator.COwner.ClassName);
            try
              FoundSpell := TSpell(OneSpell);
              FoundSpell.Originator  := Card;
              FoundSpell.Trigger     := Trigger;
              FoundSpell.CardType    := TCardType  ( FQuery.Recordset.Fields[ DB_FLD_CARD_TYPE   ].Value );
              FoundSpell.Category    := TCategory  ( FQuery.Recordset.Fields[ DB_FLD_CATEGORY    ].Value );
              FoundSpell.LifeToAdd   :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_LIFE_TO_ADD ].Value,0);
              FoundSpell.MaxRandom   :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_MAX_RANDOM  ].Value,0);
              FoundSpell.PerCent     :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_PER_CENT    ].Value,0);
              FoundSpell.Plus        :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_PLUS        ].Value,0);
              FoundSpell.ReplaceDmg  :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_REPLACE_DMG ].Value,0);
              FoundSpell.Replacement :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_REPLACEMENT ].Value,0);
              FoundSpell.StatTarget  :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_STAT_TARGET ].Value,0);
              FoundSpell.Target      := TTargetType( IfNull(FQuery.Recordset.Fields[ DB_FLD_TARGET      ].Value,0) );
              FoundSpell.Need2Target :=             IfNull( FQuery.Recordset.Fields[ DB_FLD_NEED2TARGET ].Value,0);
              assert(FoundSpell.Originator.COwner is TPlayer,'TSpellMeister.RunSpells : FoundSpell.Originator.COwner not a player: ' + OneSpell.Originator.COwner.ClassName);
              if FoundSpell.Need2Target = 1 then
                 FOnSeek2ndTarget(Card);
              FonFindSpell(FoundSpell);
            finally
              FreeAndNil(OneSpell);
            end;
            end;

      except                    // I think this is OK but is there a possible bug if
        FreeAndNil(OneSpell);   //  spell adjuster added to list then destroyed?
      end;                      // List item would then be invalid.

      FQuery.Recordset.MoveNext;
    end;
  end;
end;

所以这就是 ss_spells 单元，现在game在 i 中使用 ss_spells 单元的单元forum.create有

 FSpellMeister.OnSeek2ndTarget := self.Handle2ndTarget; 

目前不知道要在 Handle2ndTarget 中放入什么

//****************************************************************************
procedure TFGame.Handle2ndTarget(Card : TCard);
begin
  showmessage('Select a target HANDLE2ndTARGET');
end;

只是为了看看我是否至少能到达这里..

因此，如果您无法弄清楚，我的问题是，当使用foundspell.Need2ndTarget := 1事件时，如何将 ss_Spells 中的 var 设置为 TObject（tcard 或 tlabel）FOnSeek2ndTarget();

Answer 1

只需更改您的类型的签名TTargetEvt，例如：

TTargetEvt = procedure (Card : TCard; var Target: TObject) of Object;  

然后RunSpells()进行相应更新：

var
  Target: TObject;
...
if FoundSpell.Need2Target = 1 then
begin
  Target := nil;
  if Assigned(FOnSeek2ndTarget) then FOnSeek2ndTarget(Card, Target);
  // use Target as needed...
end;
...

然后相应地更新您的处理程序：

procedure TFGame.Handle2ndTarget(Card : TCard; var Target: TObject);
begin
  Target := ...;
end;