如何在IO上下文中生成函数的重复应用程序列表到其先前的结果

Question

作为我试图解决的问题的解决方案的一部分,我需要生成一个函数的重复应用列表,它的先前结果.听起来非常像迭代函数,除了迭代有签名

iterate :: (a -> a) -> a -> [a]

并且我的函数存在于IO内部(我需要生成随机数),所以我需要更多的东西:

iterate'::(a -> IO a) -> a -> [a]

我看过hoogle,但没有太大的成功.

Answer 1

如果使用pipes库,实际上可以获得一个适用于无限列表的惰性迭代.定义非常简单:

import Pipes

iterate' :: (a -> IO a) -> a -> Producer a IO r
iterate' f a = do
    yield a
    a2 <- lift (f a)
    iterate' f a2

例如,假设我们的步骤函数是:

step :: Int -> IO Int
step n = do
    m <- readLn
    return (n + m)

然后施加iterate到step产生Producer该懒惰地提示用户输入并产生迄今读值的帐簿:

iterate' step 0 :: Producer Int IO ()

读出值的最简单方法是循环Producer使用for:

main = runEffect $
    for (iterate' step 0) $ \n -> do
        lift (print n)

程序然后无休止地循环,请求用户输入并显示当前计数:

>>> main
0
10<Enter>
10
14<Enter>
24
5<Enter>
29
...

注意这是如何得到两个正确的,其他解决方案没有:

但是,我们可以像其他两个解决方案一样轻松过滤结果.例如,假设我想在计数大于100时停止.我可以写:

import qualified Pipes.Prelude as P

main = runEffect $
    for (iterate' step 0 >-> P.takeWhile (< 100)) $ \n -> do
        lift (print n)

你可以这样说:"在迭代值小于100时循环遍历它们.打印输出".我们来试试吧:

>>> main
0
10<Enter>
10
20<Enter>
30
75<Enter>
>>> -- Done!

事实上,pipes有另一个帮助函数用于打印输出值,因此您可以将上述内容简化为管道:

main = runEffect $ iterate' step 0 >-> P.takeWhile (< 100) >-> P.print

这样可以清楚地了解信息流. iterate'产生一个永无止境的Ints 流,P.takeWhile过滤流,并P.print打印到达终点的所有值.

如果您想了解有关该pipes库的更多信息,建议您阅读本pipes教程.