如何创建彩虹渐变的一部分

Question

我需要生成一个梯度位图,显示用户选择的两种颜色之间的彩虹渐变.生成彩虹很容易.我从Wiki获得了下面的代码并略微调整它.它具有快速和简单的优点.

 function TColor_Dialog.GiveRainbowColor (fraction: double): TAlphaColor;
  var
    m: Double;
    r, g, b, mt: Byte;
  begin
    if fraction <= 0 then m := 0 else
    if fraction >= 1 then m := 6
                     else m := fraction * 6;
    mt := (round (frac (m) * $FF));
    case Trunc (m) of
    0: begin
        R := $FF;
        G := mt;
        B := 0;
      end;
    1: begin
        R := $FF - mt;
        G := $FF;
        B := 0;
      end;
    2: begin
        R := 0;
        G := $FF;
        B := mt;
      end;
    3: begin
        R := 0;
        G := $FF - mt;
        B := $FF;
      end;
    4: begin
        R := mt;
        G := 0;
        B := $FF;
      end;
    5: begin
        R := $FF;
        G := 0;
        B := $FF - mt;
      end;
    end; // case

    Result := ColorToQuad (r, g, b);
  end; // GiveRainbowColor //

这个算法的麻烦是它不能在两种颜色之间显示部分彩虹.嗯,当然它可以,但你必须接近每种颜色的分数,我不喜欢这个解决方案.我尝试将颜色分解为r,g,b通道但是没有用.后见之明的原因很明显.假设您需要FF0000和0000FF之间的渐变.您将从FF-> 00转换为红色,从00-> FF转换为蓝色.然而,没有绿色(00FF00)明显存在于彩虹渐变中.

我需要的是一个渐变函数,我可以给出两种颜色和一个分数,它会产生一种颜色.谁能指点我的文章,算法甚至代码？

更新

NGLN的答案是这个问题的正确答案.他和沃伦都想知道当一个颜色不明亮时该怎么办颜色时(如果颜色包含0,$ FF和值).我尝试了几个角度:向上/向下缩放和HSL插值.我终于安顿下来,最后一个是最简单的.

基本上你有两种颜色:from和to.使用RGBtoHSL从每种颜色中提取HSL参数:RGBtoHSL (col_from, hf, sf, lf).接下来计算两种颜色之间的色调,饱和度和亮度,并重建新颜色.这就是NGLN在他关于色调的更新中提到的,但是如果你概括了这个原则,你就会在任何颜色之间产生彩虹.

function TColor_Dialog.interpolate_hsl (col_from, col_to: TAlphaColor; fraction: double): TAlphaColor;
  var af, at, ad: uInt8;
      hf, ht, hd: single;
      sf, st, sd: single;
      lf, lt, ld: single;
  begin
  // Get each rgb color channel
     af := GetAValue (col_from);
     at := GetAValue (col_to);
     RGBtoHSL (col_from, hf, sf, lf);
     RGBtoHSL (col_to,   ht, st, lt);

  // Compute differences
     ad := af + Round (fraction * (at - af));
     hd := hf + fraction * (ht - hf);
     sd := sf + fraction * (st - sf);
     ld := lf + fraction * (lt - lf);

     Result := MakeColor (HSLtoRGB (hd, sd, ld), ad);
  end; // interpolate_hsl //

这为所有可能的颜色提供了彩虹.我对不透明度应用相同的插值,因此使用MakeColor"插入"内插的alpha通道到颜色.

Answer 1

然后你需要计算彩虹中颜色的位置; 倒数GiveRainbowColor:

function RainbowIndex(BrightColor: TColor): Double;
var
  R: Byte;
  G: Byte;
  B: Byte;
begin
  R := GetRValue(ColorToRGB(BrightColor));
  G := GetGValue(ColorToRGB(BrightColor));
  B := GetBValue(ColorToRGB(BrightColor));
  if (R * G * B <> 0) or ((R <> 255) and (G <> 255) and (B <> 255)) then
    Result := -1
  else if B = 0 then
    if R = 255 then
      Result := 0 + G / 255
    else
      Result := 1 + (255 - R) / 255
  else if R = 0 then
    if G = 255 then
      Result := 2 + B / 255
    else
      Result := 3 + (255 - G) / 255
  else { G = 0 }
    if B = 255 then
      Result := 4 + R / 255
    else
      Result := 5 + (255 - B) / 255;
  Result := Result / 6;
end;

(但是这对于不具有0和255部分的颜色显示出问题.换句话说:您还需要从阴影,着色或灰色颜色计算亮色.请参阅下面的更新.)

用法示例从获得彩虹片clRed到clBlue:

procedure TForm1.FormPaint(Sender: TObject);
var
  Start: Double;
  Finish: Double;
  X: Integer;
begin
  Start := RainbowIndex(clRed);
  Finish := RainbowIndex(clBlue);
  for X := 0 to ClientWidth - 1 do
  begin
    Canvas.Brush.Color := GiveRainbowColor(0, ClientWidth - 1, X);
    Canvas.FillRect(Bounds(X, 0, 1, 50));
    Canvas.Brush.Color :=
      GiveRainbowColor(0, ClientWidth - 1, Round(Start + (Finish - Start) * X));
    Canvas.FillRect(Bounds(X, 50, 1, 50));
  end;
end;

更新:

RainbowIndex上面的例程实际上什么也没做,然后计算颜色的hue属性.该GraphUtil单元为HSL颜色模型提供转换例程,使这种RainbowIndex常规类型过时,并且具有能够提供任何TColor值的优势:

uses
  GraphUtil;

const
  HLSMAX = 240;

function Hue(AColor: TColor): Double;
var
  Hue: Word;
  Luminance: Word;
  Saturation: Word;
begin
  ColorRGBToHLS(ColorToRGB(AColor), Hue, Luminance, Saturation);
  Result := Hue / HLSMAX;
end;

用法示例从获得彩虹片clMoneyGreen到clPurple:

function RainbowColor(Hue: Double): TColor; overload;
begin
  Hue := EnsureRange(Hue, 0, 1) * 6;
  case Trunc(Hue) of
    0: Result := RGB(255, Round(Frac(Hue) * 255), 0);
    1: Result := RGB(255 - Round(Frac(Hue) * 255), 255, 0);
    2: Result := RGB(0, 255, Round(Frac(Hue) * 255));
    3: Result := RGB(0, 255 - Round(Frac(Hue) * 255), 255);
    4: Result := RGB(Round(Frac(Hue) * 255), 0, 255);
  else
    Result := RGB(255, 0, 255 - Round(Frac(Hue) * 255));
  end;
end;

function RainbowColor(MinHue, MaxHue, Hue: Integer): TColor; overload;
begin
  Result := RainbowColor((Hue - MinHue) / (MaxHue - MinHue + 1));
end;

procedure TForm1.FormPaint(Sender: TObject);
var
  X: Integer;
  Start: Double;
  Finish: Double;
begin
  Start := Hue(clMoneyGreen);
  Finish := Hue(clPurple);
  for X := 0 to ClientWidth - 1 do
  begin
    Canvas.Brush.Color := RainbowColor(0, ClientWidth - 1, X);
    Canvas.FillRect(Bounds(X, 0, 1, 50));
    Canvas.Brush.Color :=
      RainbowColor(Start + (Finish - Start) * X / ClientWidth);
    Canvas.FillRect(Bounds(X, 50, 1, 50));
  end;
end;

此外,RainbowColor例程可以缩短为:

function RainbowColor(Hue: Double): TColor; overload;
begin
  Result := ColorHLStoRGB(Round(Hue * HLSMAX), HLSMAX div 2, HLSMAX);
end;