Mic*_*Hua 11 delphi string format file
随着writeln我可以格式化数字成一条线的文字.
var
file: text;
mystring: string;
begin
writeln(file,'Result is: ', var1:8:2,' | ', var2:8:2,' |');
end;
Run Code Online (Sandbox Code Playgroud)
在Delphi中是否有一个类似的易于使用的程序,可以执行类似的结果
_format_string(mystring, 'Result is: ', var1:8:2,' | ', var2:8:2,' |');
Run Code Online (Sandbox Code Playgroud)
谢谢.
And*_*and 16
你使用的Format功能:
mystring := Format('The image dimensions are %d × %d.', [640, 480]);
Run Code Online (Sandbox Code Playgroud)
Jer*_*ers 12
从技术上讲,答案是肯定的.但不建议这样做.
您可以根据System.TTextRec类型编写自己的文本文件设备驱动程序.
我在过去(特别是Turbo Pascal时代)已经完成了这个以进行调试.这是一个大量的工作,并要求你写一个特殊的MyAssign程序,并确保关闭Text使用该文件TTextRec的try..finally块.繁琐,但可行.
更容易的替代方法是使用Andreas Rejbrand描述的Format函数.
关于使用的一个很酷的事情Format是,你使用格式字符串不仅可以参数化内部width和类似内容,还可以像通常提供值一样的参数.precisionFormat String
您可以非常接近使用width8和precision2中的a,就像问题中的示例一样.
例如,引用文档:
Format ('%*.*f', [8, 2, 123.456]);
Run Code Online (Sandbox Code Playgroud)
相当于:
Format ('%8.2f', [123.456]);
Run Code Online (Sandbox Code Playgroud)
这是一个经常被忽略的功能Format和Format Strings.
虽然Jeroen不推荐它,但我在一年前做过类似的事情 - 只是为了学习如何做到这一点.这是代码:
type
TTextFile = class
private type
TTextRecHelper = record helper for TTextRec
public
function GetTextFile: TTextFile;
procedure SetTextFile(const Value: TTextFile);
property TextFile: TTextFile read GetTextFile write SetTextFile;
end;
private var
FBuilder: TStringBuilder;
class function TextClose(var F: TTextRec): Integer; static;
class function TextIgnore(var F: TTextRec): Integer; static;
class function TextInput(var F: TTextRec): Integer; static;
class function TextOpen(var F: TTextRec): Integer; static;
class function TextOutput(var F: TTextRec): Integer; static;
procedure AppendString(const Value: string);
procedure AssignFile(var F: Text);
public
var F: Text;
constructor Create;
destructor Destroy; override;
function ToString: string; override;
end;
constructor TTextFile.Create;
begin
inherited Create;
FBuilder := TStringBuilder.Create();
AssignFile(F);
Rewrite(F);
end;
destructor TTextFile.Destroy;
begin
Close(F);
FBuilder.Free;
inherited Destroy;
end;
procedure TTextFile.AppendString(const Value: string);
begin
FBuilder.Append(Value);
end;
procedure TTextFile.AssignFile(var F: Text);
begin
FillChar(F, SizeOf(F), 0);
with TTextRec(F)do
begin
Mode := fmClosed;
BufSize := SizeOf(Buffer);
BufPtr := @Buffer;
OpenFunc := @TextOpen;
TextFile := Self;
end;
end;
class function TTextFile.TextClose(var F: TTextRec): Integer;
begin
Result := 0;
end;
class function TTextFile.TextIgnore(var F: TTextRec): Integer;
begin
Result := 0;
end;
class function TTextFile.TextInput(var F: TTextRec): Integer;
begin
F.BufPos := 0;
F.BufEnd := 0;
Result := 0;
end;
class function TTextFile.TextOpen(var F: TTextRec): Integer;
begin
if F.Mode = fmInput then
begin
F.InOutFunc := @TextInput;
F.FlushFunc := @TextIgnore;
F.CloseFunc := @TextIgnore;
end else
begin
F.Mode := fmOutput;
F.InOutFunc := @TextOutput;
F.FlushFunc := @TextOutput;
F.CloseFunc := @TextClose;
end;
Result := 0;
end;
class function TTextFile.TextOutput(var F: TTextRec): Integer;
var
AStr: AnsiString;
begin
SetLength(AStr, F.BufPos);
Move(F.BufPtr^, AStr[1], F.BufPos);
F.TextFile.AppendString(string(AStr));
F.BufPos := 0;
Result := 0;
end;
function TTextFile.ToString: string;
begin
Close(F);
result := FBuilder.ToString;
Rewrite(F);
end;
function TTextFile.TTextRecHelper.GetTextFile: TTextFile;
begin
Move(UserData[1], Result, Sizeof(Result));
end;
procedure TTextFile.TTextRecHelper.SetTextFile(const Value: TTextFile);
begin
Move(Value, UserData[1], Sizeof(Value));
end;
Run Code Online (Sandbox Code Playgroud)
根据您的问题如何使用它的示例:
tf := TTextFile.Create;
try
Writeln(tf.F, 'Result is: ', var1:8:2,' | ', var2:8:2,' |');
Caption := tf.ToString;
finally
tf.Free;
end;
Run Code Online (Sandbox Code Playgroud)