在 Emacs 中重命名当前缓冲区和相关文件

Question

我想重命名一个在 Emacs 中绑定当前缓冲区的文件。

我从这篇文章中找到了以下 elisp： 如何在 Emacs 中重命名打开的文件？

;; source: http://steve.yegge.googlepages.com/my-dot-emacs-file
(defun rename-file-and-buffer (new-name)
  "Renames both current buffer and file it's visiting to NEW-NAME."
  (interactive "sNew name: ")
  (let ((name (buffer-name))
        (filename (buffer-file-name)))
    (if (not filename)
        (message "Buffer '%s' is not visiting a file!" name)
      (if (get-buffer new-name)
          (message "A buffer named '%s' already exists!" new-name)
        (progn
          (rename-file name new-name 1)
          (rename-buffer new-name)
          (set-visited-file-name new-name)
          (set-buffer-modified-p nil))))))

它工作正常，但如果可能的话，我想将当前文件名设置为默认值。我会怎么写这个？

Answer 1

您能详细说明一下原因吗需要这样做？需要什么条件？因为自从我开始使用 Emacs 以来，从来没有出现过这个问题。

但有时当我想重命名某些内容时我会这样做：

1. 假设我正在编辑 spam-spom-spam.cc。我想修复这个名字。
2. C-x d
3. C-s spo
4. C-x C-q
5. DEL a
6. C-c C-c

这看起来似乎有很多命令，但它们的流动非常自然。作为奖励，您可以概览目录以及新重命名的文件在其中的外观。

Answer 2

最近在 Emacs Redux博客上有一篇关于这个主题的 帖子。

基本上它是在Prelude 配置（由同一作者）中实现的，您可以安装该配置以获得这种行为和大量其他有趣的东西。否则，您只能在配置文件中放入相关代码段（取自上面的博客文章）：

(defun rename-file-and-buffer ()
  "Rename the current buffer and file it is visiting."
  (interactive)
  (let ((filename (buffer-file-name)))
    (if (not (and filename (file-exists-p filename)))
        (message "Buffer is not visiting a file!")
      (let ((new-name (read-file-name "New name: " filename)))
        (cond
         ((vc-backend filename) (vc-rename-file filename new-name))
         (t
          (rename-file filename new-name t)
          (set-visited-file-name new-name t t)))))))

(global-set-key (kbd "C-c r")  'rename-file-and-buffer)