防止在Marpa :: R2 :: Scanless中进行幼稚的最长令牌匹配

Question

在当前的Marpa解析器中的Scanless Interface（SLIF）实现中，词法分析器似乎以以下方式执行最长的令牌匹配（LTM）：

1. 尝试在输入中的当前位置匹配所有端子符号。
2. 除了最长的匹配项之外的所有匹配项都将被丢弃。
3. 这些最长的令牌被馈送到解析器，解析器可以接受也可以不接受。
4. 如果不接受任何令牌，则解析失败。

当我的语法包含与最长子字符串匹配但无法在当前位置出现的标记时，这将导致令人沮丧的解析失败。考虑以下代码：

#!/usr/bin/env perl

use strict; use warnings; use feature qw/say/; use utf8;

use Marpa::R2;
use Data::Dump;

my @data = ('! key : value', '! key:value');

my $grammar = Marpa::R2::Scanless::G->new({
    source => \<<'END_GRAMMAR',
        :default ::= action => [values]
        :start   ::= record

        :discard  ~  ws
        ws        ~  [\s]+

        record ::= ('!') key (':') value
        key     ~  [\w]+
        value   ~  [^\s]+
END_GRAMMAR
});


for my $data (@data) {
    my $recce = Marpa::R2::Scanless::R->new({
        grammar => $grammar,
        trace_terminals => 0, # set this to "1" to see how the tokens are recognized
    });

    $recce->read(\$data);

    my $val = $recce->value // die "no parse";

    say ">> $data";
    dd $$val;
}

产生输出：

>> ! key : value
["key", "value"]
Error in SLIF G1 read: No lexemes accepted at position 2
* Error was at end of input
* String before error: ! key:value
Marpa::R2 exception at marpa.pl line 33.

预期产量：

>> ! key : value
["key", "value"]
>> ! key:value
["key", "value"]

后!经确认，一个key令牌必须遵循。在此位置进行词法化期间，value令牌与最长的子字符串匹配，key:value尽管它不能在此位置出现。因此，解析失败。

问题：不编写手动词法分析器就能达到预期的输出吗？

（我知道词法分析器可以查询识别器以获取预期的令牌，并且可以将自身限制为仅匹配这些令牌，但是我不知道如何说服SLIF为我执行此操作。）

我在perl5 v16.2上运行Marpa :: R2 v2.064

---

编辑

遵循Jeffrey Kegler的建议，我实现了一条规则，该规则将始终匹配比普通字符串更长的子字符串value，因此是首选规则。使用pause事件，然后我可以手动解析它，尽管我必须保留一个幻像规则以获取正确的语义。

这是完整的，更新的代码，包括。事件处理和更新的测试用例：

#!/usr/bin/env perl

use strict; use warnings; use feature qw/say/; use utf8;

use Marpa::R2;
use Data::Dump;

my @data = ('! key : value', '! key:value', '! key :value', '! key: value');

my $grammar = Marpa::R2::Scanless::G->new({
    source => \<<'END_GRAMMAR',
        :default ::= action => [values]
        :start   ::= Record

        :discard  ~  ws
        ws        ~  [\s]+

        Record ::=
                ('!') Key (<Op colon>) Value # not directly used
            |   ('!') KeyValue
        Key     ~  key
        Value   ~  value
        KeyValue~  key <ws any> ':' <ws any> value
        :lexeme ~ KeyValue pause => before event => 'before KeyValue'
        <Op colon> ~ ':'

        key     ~  [\w]+
        value   ~  [^\s]+
        <ws any>~  [\s]*
END_GRAMMAR
});

my %events = (
    'before KeyValue' => sub {
        my ($recce, $string, $start, $length) = @_;
        my ($k, $o, $v) = split /(\s*:\s*)/, $string, 2;
        say STDERR qq(k="$k" o="$o" v="$v");
        my $pos = $start;
        $recce->lexeme_read('Key'      => $pos, length($k), $k);
        $pos += length $k;
        $recce->lexeme_read('Op colon' => $pos, length($o), $o);
        $pos += length $o;
        $recce->lexeme_read('Value'    => $pos, length($v), $v);
    },
);


for my $data (@data) {
    my $recce = Marpa::R2::Scanless::R->new({
        grammar => $grammar,
        trace_terminals => 0,
    });
    my $length = length $data;
    for (
        my $pos = $recce->read(\$data);
        $pos < $length;
        $pos = $recce->resume()
    ) {
        say STDERR "pause";
        my ($start, $length) = $recce->pause_span();
        my $str = substr $data, $start, $length;
        for my $event_data (@{ $recce->events }) {
            my ($name) = @$event_data;
            my $code = $events{$name} // die "no code for event $name";
            $recce->$code($str, $start, $length);
        }
    }

    my $val = $recce->value // die "no parse";

    say ">> $data";
    dd $$val;
}

这产生

>> ! key : value
["key", "value"]
>> ! key:value
["key", "value"]
>> ! key :value
["key", "value"]
>> ! key: value
["key", "value"]

这是预期的行为。

Answer 1

请注意，自版本2.079_015以来，Marpa支持最长可接受令牌匹配的概念，这意味着只需添加：

lexeme default = forgiving => 1

您的语法将产生预期的输出。即：

#!env perl -w
use strict;
use Marpa::R2;
use Data::Dump;
use feature qw/say/;

my $grammar = Marpa::R2::Scanless::G->new({source => \do {local $/; <DATA>}});
my @data = ('! key : value', '! key:value', '! key :value', '! key: value');

foreach (@data) {
    my $r = Marpa::R2::Scanless::R->new({grammar => $grammar});
    $r->read(\$_);
    my $val = $r->value;
    say ">> $_"; dd $$val;
}
__DATA__
:default ::= action => [values]
lexeme default = forgiving => 1
:start   ::= record

:discard  ~  ws
 ws        ~  [\s]+

record ::= ('!') key (':') value
key     ~  [\w]+
value   ~  [^\s]+

会给：

>> ! key : value
["key", "value"]
>> ! key:value
["key", "value"]
>> ! key :value
["key", "value"]
>> ! key: value
["key", "value"]