如何使用Cypher返回节点的所有属性？

Question

我知道可以使用通配符(*)符号返回Cypher查询中的所有引用,例如:

MATCH p:Product WHERE p.price='1950' RETURN *;

  ==> +----------------------------------------------------------------+
  ==> | p                                                              |
  ==> +----------------------------------------------------------------+
  ==> | Node[686]{title:"Giorgio Armani Briefcase",price:"1950",...    |
  ==> +----------------------------------------------------------------+

但是,结果是一行具有名为"p"的单个节点"列",可以从中访问属性.但是,我希望结果集"行"将属性名称设置为"列".就像是:

MATCH p:Product WHERE p.price='1950' RETURN p.*;

  ==> +-------------------------------------------+
  ==> | title | price | ...                       |
  ==> +-------------------------------------------+
  ==> | "Giorgio Armani Briefcase" | "1950" | ... |
  ==> +-------------------------------------------+

该特定查询无效,但有没有办法实现相同的结果(没有明确列出所有属性,如p.title,p.price,p ...)？

Answer 1

你还不能在Cypher中做到这一点.如果您想要它,我认为这将是一个很好的功能.

编辑(感谢评论指出):您现在可以从2.2开始执行此操作:

MATCH (p:Product) WHERE p.price='1950' RETURN keys(p);

Answer 2

在最新版本的cypher properties(n)中将返回节点的所有键和属性.似乎只适用于单个节点.

我希望这有助于人们.

Answer 3

只是为了扩大获取密钥:

MATCH (p:product) WITH DISTINCT keys(p) AS keys
UNWIND keys AS keyslisting WITH DISTINCT keyslisting AS allfields
RETURN allfields;

Answer 4

这篇博文很好地展示了在 Neo4J 中操作结果

如果您只想获取密钥，上面的回复很好。

如果只想获取属性对象，而不获取

"identity": 16,
"labels": ["Post"],
"properties": { ... }

你可以做：

MATCH p:Product WHERE p.price='1950' RETURN p{.*};

这是一个涉及列表的高级示例：

MATCH (post:Post)-[:HAS_JOB]-(job)
OPTIONAL MATCH(post)-[:HAS_LIKE]-(like)
OPTIONAL MATCH (post)-[:HAS_USER]-(user)
WITH post, job, user, collect(like{.*}) as likes
RETURN post{
    .*,
    likes: likes,
    job: job{.*},
    user: user{.*}
};

结果示例：

{
    "id": "ec704f3b-ce10-4f23-bd06-6d668b7db488",
    "title": "Science Summer"
    "job": {
            "id": "81ae08e4-57d6-4997-9cb8-407e13bc30c6",
            ...
        },
    "user": null,
    "likes": [
        {
            "id": "2209e3a9-701d-4842-9d6b-d4dc8428bac6",
            "name": "alex",
            ...
        }
    ],
}

这与JavaScript 扩展运算符非常相似。