VBA - Excel：当找不到匹配项时，Vlookup 使我的程序崩溃

Question

在我的程序中，用户输入邮政编码并获取与邮政编码（省、市、区）相关的输出信息。为此，我使用 Vlookup 函数。所以，用户：

1. 在主表中输入邮政编码
   
2. 该程序在数据库（在另一张纸中）中搜索，其中邮政编码与城市、省、区相关联。
   
3. 当有匹配时，它将结果发送到主页，因此用户只需输入邮政编码即可获得城市、省份、地区。非常简单的过程。

我使用这段代码来执行此操作：

If Range("J9").Value <> "N/A" Then 'if there is actually a zip code entered by the user (if not, it will be "N/A")
cityZip = Application.WorksheetFunction.VLookup(sMain.Range("J9").Value,
                 sZipCodes.Range("B2:E864"), 3, False)
barangayZip = Application.WorksheetFunction.VLookup(sMain.Range("J9").Value,   
                 sZipCodes.Range("B2:E864"), 2, False)
provinceZip = Application.WorksheetFunction.VLookup(sMain.Range("J9").Value,    
                 sZipCodes.Range("B2:E864"), 4, False)
sMain.Range("J7").Value = provinceZip
sMain.Range("J13").Value = cityZip
sMain.Range("J16").Value = barangayZip
Else
End If

当我的数据库中有邮政编码时，它可以完美地工作。但如果没有，它会导致程序的执行崩溃，并且出现错误消息（例如“执行错误'1004'，无法读取 Vlookup ...）。如何修改我的代码以仅说明如果没有匹配项，那么它应该什么也不做？我不知道如何在 Vlookup 函数中引入这个请求。

提前致谢 ！

编辑：这是我的新代码，遵循蒂姆·威廉姆斯的建议：

'Using Zip Code
If Range("J9").Value <> "N/A" Then
provinceZip = Application.Lookup(sMain.Range("J9").Value, sZipCodes.Range("B2:E907"), 4, False)

If IsError(provinceZip) = False Then
cityZip = Application.Lookup(sMain.Range("J9").Value, sZipCodes.Range("B2:E907"), 3, False)
barangayZip = Application.Lookup(sMain.Range("J9").Value, sZipCodes.Range("B2:E907"), 2, False)

sMain.Range("J7").Value = provinceZip
sMain.Range("J13").Value = cityZip
sMain.Range("J16").Value = barangayZip
Else
'do nothing
End If

End If

我的错误在这一行：

provinceZip = Application.Lookup(sMain.Range("J9").Value, sZipCodes.Range("B2:E907"), 4, False)

=> 错误 1004，参数数量无效

Answer 1

您应该阅读 VBA 错误处理。http://www.cpearson.com/excel/errorhandling.htm等来源可能会有所帮助。也就是说，请尝试以下代码。

你想要这样的东西：

Public Function SafeVlookup(lookup_value, table_array, _
                        col_index, range_lookup, error_value) As Variant
    On Error Resume Next
    Err.Clear
    return_value = Application.WorksheetFunction.VLookup(lookup_value, _
                                table_array, col_index, range_lookup)
    If Err <> 0 Then
      return_value = error_value
    End If

    SafeVlookup = return_value
    On Error GoTo 0
End Function

在您的代码中，您可以这样称呼它：

cityZip = SafeVlookup(sMain.Range("J9").Value, sZipCodes.Range("B2:E864"), 3, _
                   False, "")

最后一个参数是 vlookup 失败时返回的默认值。所以在这个例子中它将返回一个空字符串。

Answer 2

我通常用包含默认值的 iferror() 包装 vlookup() 。

语法如下：

iferror(vlookup(....), <default value when lookup fails>)

你也可以这样做：

Dim result as variant
result = Application.vlookup(......)
If IsError(result) Then
  ' What to do if an error occurs
Else
  ' what you would normally do
End if