删除列表中指定索引处的元素

Question

我需要你的帮助！你能帮我解决这个问题吗：在 Prolog 的指定索引处删除列表中的一个元素。

例如：

    delete(List,Index,NewList).   
    ?-L=[1,5,7,4],delete(L,2,L2),write(L2).
    L2 = [1,7,4]

我不知道该怎么做。

解决了！

   away([G|H],1,H):-!.
   away([G|H],N,[G|L]):- N > 1, Nn is N - 1,!,away(H,Nn,L).
   ?-away([1,2,3,4,5],3,X), write(X). 

Answer 1

使用内置函数nth0/4（使用基于 0 的索引）或nth1/4（使用基于 0 的索引）来执行此操作。在您的情况下，由于您使用基于 1 的索引，因此nth1应使用：

nth1(Index, List, _, Remainder)

提供Indexand List，因为你不需要被删除的元素，你可以忽略它，那么结果列表将在Remainder.

这是nth1从lists.plSWI-Prolog 中的库中获取的源代码，重写以删除依赖项：

% Case 1: Index not specified
nth1(Index, In, Element, Rest) :-
    var(Index), !,
    generate_nth(1, Index, In, Element, Rest).
% Case 2: Index is specified
nth1(Index, In, Element, Rest) :-
    integer(Index), Index > 0,
    find_nth1(Index, In, Element, Rest).

generate_nth(I, I, [Head|Rest], Head, Rest).
generate_nth(I, IN, [H|List], El, [H|Rest]) :-
    I1 is I+1,
    generate_nth(I1, IN, List, El, Rest).

find_nth1(1, [Head|Rest], Head, Rest) :- !.
find_nth1(N, [Head|Rest0], Elem, [Head|Rest]) :-
    M is N-1,
    find_nth1(M, Rest0, Elem, Rest).