如何在列表推导中拥有多个无限范围？

Question

在haskell中,我有一个这样的列表理解:

sq = [(x,y,z) | x <- v, y <- v, z <- v, x*x + y*y == z*z, x < y, y < z]
    where v = [1..]

然而,当我尝试时take 10 sq,它只是冻结...有没有办法处理多个无限范围？

谢谢

Answer 1

除了解释问题的其他答案之外,这里还有一个替代解决方案,可以推广使用,level-monad并且stream-monad可以在无限搜索空间中进行搜索(它也与列表monad兼容logict,但是这些不能很好地与无限搜索一起使用)搜索空间,正如您已经发现的那样):

{-# LANGUAGE MonadComprehensions #-}

module Triples where

import Control.Monad

sq :: MonadPlus m => m (Int, Int, Int)
sq = [(x, y, z) | x <- v, y <- v, z <- v, x*x + y*y == z*z, x < y, y < z]
    where v = return 0 `mplus` v >>= (return . (1+))

现在,快速广度优先搜索:

*Triples> :m +Control.Monad.Stream
*Triples Control.Monad.Stream> take 10 $ runStream sq
[(3,4,5),(6,8,10),(5,12,13),(9,12,15),(8,15,17),(12,16,20),(7,24,25),
(15,20,25),(10,24,26),(20,21,29)]

或者:

*Triples> :m +Control.Monad.Levels
*Triples Control.Monad.Levels> take 5 $ bfs sq   -- larger memory requirements
[(3,4,5),(6,8,10),(5,12,13),(9,12,15),(8,15,17)]
*Triples Control.Monad.Levels> take 5 $ idfs sq  -- constant space, slower, lazy
[(3,4,5),(5,12,13),(6,8,10),(7,24,25),(8,15,17)]

Answer 2

列表推导被转换为concatMap函数的嵌套应用程序:

concatMap :: (a -> [b]) -> [a] -> [b]
concatMap f xs = concat (map f xs)

concat :: [[a]] -> [a]
concat [] = []
concat (xs:xss) = xs ++ concat xss

-- Shorter definition:
--
-- > concat = foldr (++) []

你的例子等同于:

sq = concatMap (\x -> concatMap (\y -> concatMap (\z -> test x y z) v) v) v
    where v = [1..]
          test x y z = 
              if x*x + y*y == z*z
              then if x < y
                   then if y < z
                        then [(x, y, z)]
                        else []
                   else []
              else []

这基本上是一种"嵌套循环"方法; 它首先尝试x = 1, y = 1, z = 1,然后继续前进x = 1, y = 1, z = 2,依此类推,直到它将所有列表的元素作为值z; 只有这样才能继续尝试组合y = 2.

但是当然你可以看到问题 - 因为列表是无限的,我们永远不会耗尽值来尝试z.所以组合(3, 4, 5)只能在无限多个其他组合之后发生,这就是你的代码永远循环的原因.

为了解决这个问题,我们需要以更智能的方式生成三元组,这样对于任何可能的组合,生成器在经过一些有限的步骤后到达它.研究这段代码(只处理对,而不是三元组):

-- | Take the Cartesian product of two lists, but in an order that guarantees
-- that all combinations will be tried even if one or both of the lists is 
-- infinite:
cartesian :: [a] -> [b] -> [(a, b)]
cartesian [] _ = []
cartesian _ [] = []
cartesian (x:xs) (y:ys) = 
    [(x, y)] ++ interleave3 vertical horizontal diagonal
        where 
          -- The trick is to split the problem into these four pieces:
          --
          -- |(x0,y0)| (x0,y1) ... horiz
          -- +-------+------------
          -- |(x1,y0)| .
          -- |   .   |  .
          -- |   .   |   .
          -- |   .   |    . 
          --   vert         diag
          vertical = map (\x -> (x,y)) xs
          horizontal = map (\y -> (x,y)) ys
          diagonal = cartesian xs ys


interleave3 :: [a] -> [a] -> [a] -> [a]
interleave3 xs ys zs = interleave xs (interleave ys zs)

interleave :: [a] -> [a] -> [a]
interleave xs [] = xs
interleave [] ys = ys
interleave (x:xs) (y:ys) = x : y : interleave xs ys

要理解这段代码(如果我搞砸了就修好了!)看看这篇关于如何计算无限集的博客文章,特别是第四张图 - 该函数是一个基于"zigzag"的算法!

我刚试过一个简单版本的你sq使用它; 它(3,4,5)几乎立即发现,但是需要很长时间才能达到任何其他组合(至少在GHCI中).但我认为从中汲取的主要教训是:

1. 列表推导仅适用于嵌套无限列表.
2. 不要花太多时间玩列表推导.他们可以做的一切,功能如此map,filter并且concatMap可以做 - 以及列表库中还有许多其他有用的功能,所以请集中精力.

Answer 3

这是可能的，但您必须想出生成数字的顺序。下面生成你想要的数字；请注意，测试可以通过仅生成are和类似的 for （确定一次并绑定）x < y来替换：y>xzxy

[(x, y, z) | total <- [1..]
           , x <- [1..total-2]
           , y <- [x..total-1]
           , z <- [total - x - y]
           , x*x + y*y == z*z]