Groovy命名参数导致参数分配切换 - 任何解决方法？

Question

Groovy会将所有命名参数收集到一个映射中,并将其作为第一个参数传递给方法.这似乎很整洁,但在尝试使其工作后,它似乎真的无法使用.

所以问题是这样的方法:

def method(paramMap, specificVar1 = 7, specificVar2 = 14)

当你用这样的方法调用这个方法时:

method(12, extraValue: "hello")

你得到了很多你期望的东西:

assert 12 == specificVar1
assert 14 == specificVar2
assert [extraValue:"hello"] == paramMap

不错,有道理.问题是,如果你认为Mapparams是可选的,你可以得到这样的值:

method(12)

assert paramMap == 12
assert specificVar1 == 7 // default values
assert specificVar2 == 14

那个标量应该进入特定的变量 - 而不是地图.如果我在方法中专门输入地图:

def method(Map paramMap, specificVar1 = 7, specificVar2 = 14)

然后method(12, extraValue: "hello")像以前一样工作,但method(12)抛出一个ClassCastException.这似乎没用.有没有办法让它变得Map"粘",如果没有Map参数它就会变成空的？

Answer 1

在参数上设置默认值会创建使用从左到右组合的重载方法,因此,很难制作method(12)并且也能够传递地图条目.

您的方法def method(paramMap, specificVar1=7, specificVar2=14)将生成以下方法:

Object Maps.method(java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object)
Object Maps.method(java.lang.Object,java.lang.Object,java.lang.Object)

以及带有map param的完全类型化方法:

def method3(Map paramMap=[:], Integer specificVar1=7, Integer specificVar2=14) {
}

将生成以下方法:

Object Maps.method3()
Object Maps.method3(java.util.Map)
Object Maps.method3(java.util.Map,java.lang.Integer)
Object Maps.method3(java.util.Map,java.lang.Integer,java.lang.Integer)

(没有合适的方法method(12)).

此外,将收集传递给该方法的条目并将其插入第一个map参数中.以下方法:

def method4(Integer specificVar1=7, Integer specificVar2=14, Map map=[:]) {

产生:

Object Maps.method4()
Object Maps.method4(java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer)
Object Maps.method4(java.lang.Integer,java.lang.Integer,java.util.Map)

因此,method4 12, a:'b'失败了:

No signature of method: Maps.method4() is applicable for argument types: 
  (java.util.LinkedHashMap, java.lang.Integer) values: [[a:b], 12]

所以,不,我不认为你可以使用地图做你想做的事情:-).

解决方案1:

如果您使用的是纯动态解决方案,则可以使用单个map参数:

def method5(Map map) {
  def specificVar1 = map.specificVar1 ?: 7
  def specificVar2 = map.specificVar2 ?: 14
}

解决方案2(更新):

您可以创建一个类来表示参数.使用地图强制进入对象是静态可编译的并且是它的合成糖.

@groovy.transform.CompileStatic
class Maps {
  def method6(Foo foo) { "$foo.params, $foo.specificVar1, $foo.specificVar2" }
  def method6(Map map) { method6 map as Foo }

  static main(args) {
    def maps = new Maps()

    assert maps.method6(params: [a: 'b', c: 'd'], specificVar1: 40) ==
        "[a:b, c:d], 40, 14"

    assert maps.method6(new Foo(params: [a: 'b', c: 'd'], specificVar2: 21)) == 
        "[a:b, c:d], 7, 21"
  }
}

class Foo {
  def specificVar1 = 7, specificVar2 = 14, params = [:]
}

解决方案3:

一个重载的方法.

def method6(Map paramMap, Integer specificVar1=7, Integer specificVar2=14) {
  "$paramMap, $specificVar1, $specificVar2"
}

def method6(Integer specificVar1=7, Integer specificVar2=14) {
  method6 [:], specificVar1, specificVar2
}


assert method6( 12 ) == "[:], 12, 14"
assert method6( ) == "[:], 7, 14"
assert method6( a:'b', 18 ) == "[a:b], 18, 14"
assert method6( 18, a:'b', 27 ) == "[a:b], 18, 27"
assert method6( 90, 100 ) == "[:], 90, 100"
assert method6( a:'b', 140, c:'d' ) == "[a:b, c:d], 140, 14"

地图版本方法不能有默认参数,否则两种方法都会生成无参数method6且会发生冲突.