动态记录访问

Question

我是delphi的新相对论,并试图为我的a2计算课程编写一个复杂的搜索算法.我需要从字符串变量访问我的记录字段.例如

         getfield(record,'name');

我发现一篇文章可以解决我的问题,但我无法理解它.请有人可以将它缩短到我需要的地方.谢谢.

http://theroadtodelphi.wordpress.com/2010/10/10/fun-with-delphi-rtti-dump-a-trttitype-definition/

Answer 1

从他们的评论中简单地修改LU RD的代码.这在Delphi XE2下编译和工作,但早期版本也应该没问题.

program Project4;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, RTTI, TypInfo;

type
  TSampleRecord = record
    SomeInt: Integer;
    SomeStr: String;
    SomeFloat: Single;
  end;

function GetField(Rec: TValue; const FieldName: String): String;
var
  Context: TRTTIContext;
  RTTIRecord: TRTTIRecordType;
  RecField: TRTTIField;
  RecValue: TValue;
begin
  if (Rec.Kind = tkRecord) then
  begin
    RTTIRecord := Context.GetType(Rec.TypeInfo).AsRecord;
    RecField := RTTIRecord.GetField(FieldName);

    RecValue := RecField.GetValue(Rec.GetReferenceToRawData);
    Result := RecValue.ToString();

    if (RecValue.Kind = tkFloat) then
      Result := Format('%.4f', [RecValue.AsExtended]);
  end;
end;

var
  SR: TSampleRecord;
begin
  SR.SomeInt := 1992;
  SR.SomeStr := 'Lorem ipsum dolor sit amet';
  SR.SomeFloat := 3.1415;

  Writeln(GetField(TValue.From(SR), 'SomeInt'));
  Writeln(GetField(TValue.From(SR), 'SomeStr'));
  Writeln(GetField(TValue.From(SR), 'SomeFloat'));

  Readln;
end.