如何为ls的输出列着色？

Question

标题样的说，这一切：我想获得的东西，如输出的那些整齐的彩色列ls -al，也就是说，在10basetom的回答到这个问题。

Answer 1

这是可行的awk。不幸的是，由于ls -l未指定的格式，因此不可能提出适用于每个系统的解决方案，因此在某些系统上需要对用于哪个列的颜色进行一些调整。

首先，我们要保留ls -l. 否则，列对齐将不正确。FPAT由于这个 SO 答案，我们可以使用该选项来做到这一点：

ls -la | awk '
    BEGIN {
        FPAT = "([[:space:]]*[^[:space:]]+)";
        OFS = "";
    }

在 中awk，每个位置参数（$1、$2等） 指的是一个字段，即当前行上的一列。FPAT上面的选项所做的是重新定义每个字段以包含所有前面的空格，因此当您print退出时，它会保留空格，以便列保持在相同的位置。

现在我们可以简单地编辑每个字段以插入颜色代码，然后打印编辑后的输出：

    {
        $2 = "\033[31m" $2 "\033[0m";
        $3 = "\033[36m" $3 "\033[0m";
        $4 = "\033[36m" $4 "\033[0m";
        $5 = "\033[31m" $5 "\033[0m";
        $6 = "\033[36m" $6 "\033[0m";
        $7 = "\033[36m" $7 "\033[0m";
        $8 = "\033[31m" $8 "\033[0m";
        print
    }
'

请注意，每列之后都会重置回默认值（0介于[和之间m）。如果您希望颜色跨越多列，则可以省略该代码。就个人而言，我更喜欢独立指定每一列。

您可以在.bashrc. 例如：

lsc() {
    ls -la | awk '
        BEGIN {
            FPAT = "([[:space:]]*[^[:space:]]+)";
            OFS = "";
        }
        {
            $2 = "\033[31m" $2 "\033[0m";
            $3 = "\033[36m" $3 "\033[0m";
            $4 = "\033[36m" $4 "\033[0m";
            $5 = "\033[31m" $5 "\033[0m";
            $6 = "\033[36m" $6 "\033[0m";
            $7 = "\033[36m" $7 "\033[0m";
            $8 = "\033[31m" $8 "\033[0m";
            print
        }
    '
}

您可能需要重新启动bash会话（或运行source ~/.bashrc）才能运行此函数定义。

从这里，您只需调用lsc，它就会为您提供所需的输出：

Answer 2

这将以ls -alF红色打印第二列，以蓝色打印第三到第八列，以黑色打印第九列：

ls -alF | awk -v black=$(tput setaf 0) -v red=$(tput setaf 1) -v blue=$(tput setaf 4) '{$2=red $2; $3= blue $3; $9=black $9} 1'

这只是一个例子。您可以根据自己的喜好对此进行自定义。

对于那些喜欢将代码分散在多行上的人：

ls -alF | awk -v black=$(tput setaf 0) \
    -v red=$(tput setaf 1) \
    -v blue=$(tput setaf 4) \
    '{
        $2=red $2
        $3= blue $3
        $9=black $9
     }

     1'

细节

tput是为您的终端生成各种控制代码的实用程序。例如， tput setaf n将前景颜色到n其中n的范围可以从0到7

0 – Black
1 – Red
2 – Green
3 – Yellow
4 – Blue
5 – Magenta
6 – Cyan
7 – White

您可以在此处阅读有关tput其颜色功能的更多信息。

awk 代码定义了变量black、red和blue，它们分别包含黑色、红色和蓝色的终端代码。这些代码放置在我们想要着色的任何列的开头。

一个技巧是颜色代码不会自行重置。因此，无论您在一行中指定的最后一种颜色，除非指定了另一个颜色命令，否则将成为下一行的默认颜色。