如何通过命令行在 Windows 中显示/隐藏隐藏文件？

Question

我经常需要在 PC 中的显示/隐藏隐藏文件之间切换。我一直按照往常的方式做，

• 在资源管理器窗口中单击组织。
• 选择文件夹和搜索选项。
• 切换到查看选项卡。
• 在显示/隐藏隐藏文件之间切换。

这种方法太冗长了，我已经厌倦了。

我想从命令行（cmd）在它们之间切换。有没有办法实现这一目标？

此外，从命令行在显示/隐藏系统文件之间切换的方法会很棒。

Answer 1

隐藏文件、文件夹或驱动器：

/f将值添加（或覆盖）Hidden到注册表项：HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced。

展示：

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 1 /f

不显示：

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 2 /f

ToggleHiddenFiles.bat

REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden | Find "0x2"
IF %ERRORLEVEL% == 1 goto turnoff
If %ERRORLEVEL% == 0 goto turnon

goto end
:turnon
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 1 /f
goto end

:turnoff
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 2 /f
goto end

:end

隐藏受保护的操作系统文件（推荐）

检查：

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 0 /f

未选中：

reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 1 /f

ToggleSystemFiles.bat

REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden | Find "0x0"
IF %ERRORLEVEL% == 1 goto turnoff
If %ERRORLEVEL% == 0 goto turnon

goto end
:turnon
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 1 /f
goto end

:turnoff
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 0 /f
goto end

:end

注意：更改会立即发生。该程序reg需要管理员权限，因此请以管理员身份运行批处理文件。