批量压缩 700GB 的 PST 文件？

Question

我正在进行存档迁移，其中我从 700GB 的 PST 文件中提取邮件，并将其发送到电子邮件存档。提取消息后，将使用自定义实用程序将其从 PST 文件中删除。

然而，这给我留下了 700GB 的大部分空 PST 文件。

出于合规性原因，我需要保留无法提取的消息，并且还需要回收磁盘空间。

有没有办法批量压缩 PST 文件？我在网上找不到很多有用的软件来做到这一点。

如果我使用一个 500MB 的 PST 文件并压缩它，我会得到一个 230MB 的存档。但是，如果我使用 Outlook 2007 来压缩它，我会剩下 15MB PST。

有人对如何批量压缩数千个 PST 文件有任何想法吗？我不是在寻找像 CompressPST 这样的解决方案来删除附件等等，因为文件 99% 是空的。

我找不到 Outlook 的任何命令行开关来完成此操作。

Answer 1

好的，我使用SmartPST（免费软件）和AutoIT（免费软件）完成了这一任务。

借助 SmartPST，我可以将 PST 文件批量添加到我的 Outlook 配置文件中。拖放。

我挖出的以下 AutoIT 脚本会迭代每个脚本并进行压缩。在虚拟机中运行它，不会避免您当前的工作。

这最终是我能要求的最好的。拖放，然后单击解决方案。:) IT 自动化没有比这更好的了。

#include <GUIListView.au3>
SplashTextOn("Compacting now", "This may take hours...", 250, 40)
;//Runs the mail application that is in control panel.
$Path = FileGetShortName(RegRead("HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Control Panel\Cpls", "mlcfg32.cpl"))
Run(@SystemDir & "\control.exe " & $Path)
Opt("WinTitleMatchMode", 4)
WinWait("Mail Setup - Outlook", "Setup e-mail accounts and dire")
ControlClick("Mail Setup - Outlook", "Setup e-mail accounts and dire", "Button2")
WinWait("Account Settings", "AcctMgr Tab")
;//Gets list of data files listed
$sTitle = "Account Settings"
$hWnd = WinGetHandle($sTitle)
If @error Then
 MsgBox(0, "Error", "Unable to find window")
EndIf
WinActivate($hWnd)
$hlist = ControlGetHandle($hWnd, "", "[CLASS:SysListView32; INSTANCE:2]")
If @error Then Exit
$arraycount = _GUICtrlListView_GetItemCount($hlist)
Local $ltext[$arraycount]
$i = 0
Do
 $ltext[$i] = _GUICtrlListView_GetItemText($hlist, $i)
 $i = $i + 1
Until $i = $arraycount
;//Goes into each listed Data file and compresses them
$b = 0
Do
 _GUICtrlListView_ClickItem($hlist, $b, "left", False, 2)
 Sleep(1000)
 WinWaitActive("Outlook Data File")
 ControlClick("Outlook Data File", "", "[CLASS:Button; INSTANCE:2]") ; click Compact Now
 Sleep(1200)
 If WinExists("Compact Now") Then WinWaitClose("Compact Now")
 WinClose("Outlook Data File")
 $b = $b + 1
Until $b = $arraycount
WinClose("Outlook Data Files")
WinClose("Account Settings")
WinClose("Mail Setup - Outlook")
SplashOff()
MsgBox(64, "Outlook", "All accounts were processed." & @CRLF & "Closing in 5 seconds...", 5)
Exit