Windows 7 托盘图标不可见

Question

托盘图标仍然存在，但它们只是不可见。再多的点击也不会对他们有任何影响。

结束然后运行explorer.exe是一个快速修复，但是图标会在重新启动时返回到它们的不可见状态。我已经处理这个问题有一段时间了，它开始让我紧张。

我已经阅读了很多文章并尝试了一堆“解决方案”，例如：

• 从注册表中删除iconstreams和删除pasticonstreams
• 安装杀毒软件
• 清除 Windows 图标缓存

但这些都没有奏效。

任何帮助都是极好的。

你能一直重现这个问题吗？ 是的，每次我重新启动计算机时，它们都会消失。

那些看不见的图标总是相同的吗？ 通常它们往往是相同的，但有时 Skype 是隐藏的，有时则不是，例如。

您是否sfc /scannow以管理员身份在命令提示符下运行？

Windows 资源保护未发现任何完整性违规。

Answer 1

取自文章 如何重置通知区域图标缓存 是文件 Reset_Notification_Area_Icons_Cache.bat。

您可以下载该文件，但该文件的内容也转载如下：

:: Created by: Shawn Brink
:: http://www.sevenforums.com
:: Tutorial:  http://www.sevenforums.com/tutorials/13102-notification-area-icons-reset.html

@echo off
cls
set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
set regKey1=IconStreams
set regKey2=PastIconsStream
set choice=Bad-Response

echo The Explorer process must be killed to reset the Notification Area Icons Cache. 
echo.
echo Please SAVE ALL OPEN WORK before continuing
echo.
pause

echo.
taskkill /IM explorer.exe /F
echo.
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto iconstreams
echo Registry key "IconStreams" already deleted.
echo.

:verify-PastIconsStream
FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
echo Registry key "PastIconsStream" already deleted.
echo.
goto confirm-restart

:iconstreams
reg delete "%regpath%" /f /v "%regkey1%"
goto verify-PastIconsStream

:PastIconsStream
reg delete "%regpath%" /f /v "%regkey2%"

:confirm-restart
echo.
echo.
echo Windows must be restarted to finish resetting the Notification Area Icons. 
echo.

:wrong 
set /p choice=Restart now? (Y/N) and press Enter:
If %choice% == y goto Yes
If %choice% == Y goto Yes
If %choice% == n goto No
If %choice% == N goto No
set choice=Bad-Response
goto wrong

:Yes
shutdown /R /f /t 00
exit

:No
echo.
echo Restart aborted. Please remember to restart the computer later.
echo.
echo You can now close this command prompt window.
explorer.exe

文章中包含运行此批处理文件的详细说明。

Answer 2

@arielnmz 的以下评论似乎解决了我的问题：

did you try removing suspicious applications from startup, not by an antivirus
or anti-malware, but manually with msconfig.exe?

那里没有什么不寻常的东西，但禁用其中的一些已经解决了我的问题。