有没有办法控制 Emacs 在哪个窗口中打开新缓冲区？

Question

我在 emacs 中使用 sr-speedbar，我经常将框架分成 2-3 个不同的窗口，每当我单击 sr-speedbar 中的文件时，它总是在最低的窗口中打开新缓冲区。我试图将最右下角的窗口保持为一个相对较小的 ansi-term，而 emacs 一直坚持在小型 term 窗口中打开新缓冲区，而不是在我想用于编辑缓冲区的更大区域中打开新缓冲区。

有什么方法可以配置缓冲区创建逻辑，使其更喜欢较高的窗口而不是较低的窗口？

我已经尝试将最低的窗口标记为受保护的，这只会让 emacs 将其分成两个不合理的小部分。然后我尝试启用窗口大小固定，而不是让 emacs 打开该窗口上方的缓冲区，它只是给了我一个错误，即窗口太小而无法拆分。很好，我猜它停止了破坏我最低的窗口，但愚蠢的是它阻止我打开新的缓冲区。

理想情况下，我希望能够强制 emacs 选择最右上角的窗口来显示新创建的缓冲区，而不是尝试拆分最右下角的窗口。

Answer 1

我假设您使用的是 Emacs 24；我没有在任何早期版本中测试过这个答案，也不知道专用窗口的概念是什么时候添加到 Emacs 中的。我已经看到从 2011 年开始提到它的使用，所以我认为 Emacs 23（至少）也有能力。

您可以通过将窗口专用于其缓冲区来防止 Emacs 在给定窗口中打开新缓冲区。

在最简单的情况下，您可以通过选择您希望专用的窗口来完成此操作，确保它当前显示您希望专用的缓冲区，然后执行M-: (set-window-dedicated-p (selected-window) t). 这将阻止 Emacs 在决定在哪个窗口中显示缓冲区时考虑这样修改的窗口。要删除奉献，请评估相同的表达式，将第二个参数替换为nil。

您可以防止 Emacs 尝试拆分显示给定缓冲区的窗口，将缓冲区局部变量 window-size-fixed 设置为非 nil 值。

在最简单的情况下，您可以通过选择窗口并执行M-: (setq window-size-fixed t). 要仅修复显示缓冲区的窗口的高度或宽度，请评估相同的表达式，传递'height或'width作为第二个参数；要取消限制，请将第二个参数替换为nil。

在一般情况下，我发现您的问题足够有趣，可以编写一个解决方案，您可以将其放入加载路径中(require)，然后使用：

;;; dedicate-windows-manually.el --- Manually (un)dedicate windows

;; Copyright (C) 2013 Aaron Miller
;; <me@aaron-miller.me>

;; This program is free software; you can redistribute it and/or
;; modify it under the terms of the GNU General Public License as
;; published by the Free Software Foundation; either version 2 of
;; the License, or (at your option) any later version.

;; This program is distributed in the hope that it will be
;; useful, but WITHOUT ANY WARRANTY; without even the implied
;; warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
;; PURPOSE.  See the GNU General Public License for more details.

;; You should have received a copy of the GNU General Public
;; License along with this program; if not, write to the Free
;; Software Foundation, Inc., 59 Temple Place, Suite 330, Boston,
;; MA 02111-1307 USA

;;; Commentary:

;; Introduction
;; ============

;; The functions here defined allow you to manually dedicate and
;; undedicate windows, that is, prevent `set-window-buffer' from
;; considering them when selecting a window in which to display a
;; given buffer.

;; Windows dedicated in this fashion will also be protected from
;; splitting by setting `window-size-fixed'.

;; Installation
;; ============

;; Place this file in your load path; then, place the following
;; command somewhere in your initialization file:

;; (require 'dedicate-windows-manually)

;; Now you can use M-x dedicate-window to dedicate the selected window
;; to its currently displayed buffer, M-x undedicate-window to release
;; a dedication so applied, and M-x dedicate-window-toggle to switch
;; between the states.

;; These functions will operate only on manually dedicated or
;; undedicated windows; that is, M-x dedicate-window will not dedicate
;; a window which is already dedicated (i.e. "(window-dedicated-p
;; window) -> t", and M-x undedicate-window will not undedicate a
;; window which was not dedicated by way of M-x dedicate-window.

;; If you find yourself frequently doing M-x dedicate-window-toggle,
;; you might wish to place something like this in your init file:

;; (global-set-key (kbd "C-x 4 C-d") 'dedicate-window-toggle)

;; Bugs:
;; * Changing the lighter string while you have windows dedicated is
;;   probably not a good idea.
;; * I should certainly find a better way to change the mode line.

;;; Code:

(defcustom dedicated-window-lighter-string " [D]"
  "A string, propertized with `dedicated-window-lighter-face', prepended
to the mode line of manually dedicated windows.")

(defvar dedicated-windows-by-hand nil
  "A list of windows known to have been manually dedicated. Windows not
in this list will not be undedicated by `undedicate-window'.")

(defun dedicate-window-was-by-hand-p (window)
  (let ((result nil))
    (loop for w in dedicated-windows-by-hand
          collect (if (eq w window) (setq result t)))
    result))

(defun dedicate-window (&optional window flag)
  "Dedicate a window to its buffer, and prevent it from being split.

Optional argument WINDOW, if non-nil, should specify a window. Otherwise,
or when called interactively, the currently selected window is used.

Optional argument FLAG, if non-nil, will be passed verbatim to
`set-window-dedicated-p'."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (eq nil flag) (setq flag t))
  (if (window-dedicated-p window)
      (message "Window is already dedicated.")
    (progn
      (add-to-list 'dedicated-windows-by-hand window)
      (setq mode-line-format
            (append `(,dedicated-window-lighter-string) mode-line-format))
      (setq window-size-fixed t)
      (set-window-dedicated-p window flag))))

(defun undedicate-window (&optional window)
  "Un-dedicate a window from its buffer.

Optional argument WINDOW, if non-nil, should specify a window listed in
`dedicated-windows-by-hand'. Otherwise, or when called interactively,
the currently selected window is used.

If WINDOW is not in `dedicated-windows-by-hand', a complaint will be
issued and nothing will be done."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (not (window-dedicated-p window))
      (message "Window is not dedicated.")
    (if (not (dedicate-window-was-by-hand-p window))
        (message "Window is not dedicated by hand.")
      (progn
        (setq dedicated-windows-by-hand
              (remove window dedicated-windows-by-hand))
        (setq mode-line-format
              (remove dedicated-window-lighter-string mode-line-format))
        (setq window-size-fixed nil)
        (set-window-dedicated-p window nil)))))

(defun dedicate-window-toggle (&optional window)
  "Toggle a window's manual buffer dedication state.

Optional argument WINDOW, if non-nil, should specify a window. Otherwise,
or when called interactively, the value of `selected-window' is used."
  (interactive nil)
  (if (eq nil window) (setq window (selected-window)))
  (if (window-dedicated-p window)
      (undedicate-window window)
    (dedicate-window window)))

(provide 'dedicate-windows-manually)

;;; dedicate-windows-manually.el ends here