在 Outlook2010 中，有没有办法查看当前正在打盹的提醒？

Question

Outlook 2010 中是否有任何方法可以拉出当前暂停的项目列表？例如，假设两周后我设置了一个提醒，以便在下周一的重要午餐会议上在周五弹出（我喜欢在周末之前提醒周一的任务）。当提醒在周五弹出时，我将其延后三天，以便在周一午餐前再次弹出。然后星期一来了，我的记忆模糊了，我有点偏执，因为我不小心在星期五取消了提醒而不是正确地打盹。我仍然可以在我的日历上看到原始约会，但我需要确保我真的会在我期望的时候弹出提醒，这样我就不会错过我的会议。

Outlook 2010 中是否有任何方法可以拉出当前暂停的提醒列表？这对于我完成一项任务的情况也很有帮助，该任务的提醒我已经延后，现在我想拉起已延后的提醒并取消它。

Answer 1

Sub SnoozedReminders()

' http://www.jpsoftwaretech.com/check-your-outlook-reminders-in-vba/

Dim MyReminder As Outlook.Reminder
Dim MyReminders As Outlook.Reminders
Dim Report As String
Dim i As Long

Set MyReminders = Outlook.Reminders

i = 0

For Each MyReminder In MyReminders

    If HasReminderFired(MyReminder) = True Then
        i = i + 1
        Report = Report & i & ": " & MyReminder.Caption & vbCr & _
            "     Snoozed to " & MyReminder.NextReminderDate & vbCr & vbCr
    End If

Next MyReminder

CreateReportAsEmail "Snoozed Items", Report

End Sub


Function HasReminderFired(rmndr As Outlook.Reminder) As Boolean
    HasReminderFired = (rmndr.OriginalReminderDate <> rmndr.NextReminderDate)
End Function


' VBA SubRoutine which displays a report inside an email
' Programming by Greg Thatcher, http://www.GregThatcher.com

Public Sub CreateReportAsEmail(Title As String, Report As String)

    On Error GoTo On_Error

    Dim Session As Outlook.Namespace
    Dim mail As MailItem
    Dim MyAddress As AddressEntry
    Dim Inbox As Outlook.folder 

    Set Session = Application.Session
    Set Inbox = Session.GetDefaultFolder(olFolderInbox)
    Set mail = Inbox.items.Add("IPM.Mail")

    mail.Subject = Title
    mail.Body = Report

    mail.Save
    mail.Display

Exiting:
    Set Session = Nothing
    Set Inbox = Nothing
    Set mail = Nothing
    Exit Sub

On_Error:
    MsgBox "error=" & Err.Number & " " & Err.Description
    Resume Exiting

End Sub

如果您不熟悉 VBA，请参阅Slipstick 的解释页面。您将找到有关以下方面的信息：

• 宏安全设置；
• 将代码放在哪里（您可以使用带有 Insert | Module 的常规模块）；和
• 如何创建一个按钮。