使用 .bat 脚本覆盖映射的驱动器名称？

Question

我有以下批处理脚本，它成功地为我们的用户映射了一些驱动器：

@echo off
net use * /delete /yes
net use x: \\192.168.1.52\xrays
net use s: \\192.168.1.52\common
net use p: \\192.168.1.52\public
net use o: \\192.168.1.52\office
net use y: \\192.168.1.52\drives
EXIT

映射的驱动器本身从共享名称中获取它们的名称。但是，如果我可以将名称覆盖为对用户更有用的名称，那将非常方便。

我在网上查看了很多带有 net use 命令示例的文档，但我只能看到诸如凭据之类的选项，而与命名无关。

该脚本正在 Windows XP 和 Windows 7 工作站上运行。

任何帮助，将不胜感激。

Answer 1

有一种方法可以在不使用 VBScript 的情况下从命令行执行此操作。您可以使用该reg add命令编辑注册表。恕我直言，这样做会比使用 VBScript 更改标签更好，因为它不会将标签与驱动器号相关联，而是将标签与共享相关联。因此，如果最终用户稍后断开连接X:并手动安装xrays共享以表示R:驱动器，那么标签仍会正确显示（无论您在脚本中分配给它什么）。

您将写入HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\的键是子键是共享路径，所有反斜杠都替换为井号 (#)。

注意： 我还没有测试过如何处理包含空格（甚至英镑符号）的共享名称。

@echo off

net use * /delete /yes

:: Set the label in the registry
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##192.168.1.52#xrays /v _LabelFromReg /t REG_SZ /f /d "X-Rays"
:: Map the drive
net use x: \\192.168.1.52\xrays

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##192.168.1.52#common /v _LabelFromReg /t REG_SZ /f /d "Common"
net use s: \\192.168.1.52\common

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##192.168.1.52#public /v _LabelFromReg /t REG_SZ /f /d "Public"
net use p: \\192.168.1.52\public

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##192.168.1.52#office /v _LabelFromReg /t REG_SZ /f /d "Office"
net use o: \\192.168.1.52\office

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\MountPoints2\##192.168.1.52#drives /v _LabelFromReg /t REG_SZ /f /d "Drives"
net use y: \\192.168.1.52\drives

EXIT