用于切换“查找结果”窗口的 Notepad++ 键盘快捷键

Question

是否有键盘快捷键来切换“查找结果”窗口？或者这可以在快捷方式映射器中配置吗？我似乎找不到设置。

Answer 1

有时我找不到“搜索结果”窗口。我按 F7 显示它但没有运气，而且我知道我也没有将窗口作为单独的窗口取消停靠。然后，有人建议我可能将它一直最小化到状态栏。所以，如果你不小心这样做了：

1. 将鼠标移到状态栏的顶部
2. 光标将变为垂直调整大小形状
3. 按住鼠标左键单击，向上拖动以显示丢失的搜索结果窗口

另请注意，“搜索结果”窗口也可以停靠在窗口的左侧、右侧或顶部。如果将鼠标悬停在状态栏的顶部时没有出现垂直调整大小形状，请尝试将光标移动到这些边附近。出现垂直状态栏后，只需单击鼠标左键，然后向窗口中央向内拖动即可显示丢失的搜索结果窗口。

我希望这个建议可以帮助其他一些和我一样感到沮丧的人。

Answer 2

我只有一半的答案——你可能已经知道了......

F7显示“搜索结果”窗口，并允许您从它跳转到编辑部分并返回到它。但我找不到隐藏/关闭它的方法。

Answer 3

无法直接在 中执行此操作Notepad++，但可以使用AutoHotKey。以下脚本将从F7仅打开的快捷方式转换为切换；如果它尚未打开，则将其打开，如果已打开，则将其关闭。

这是脚本：

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; Ed Cottrell's AutoHotKey script for toggling the "Find Results" pane/window in Notepad++
; Released under the MIT License (http://opensource.org/licenses/MIT)
; Version: 1.1
; Release Date: January 15, 2014
; Released on Superuser.com: http://superuser.com/questions/700357/create-a-hotkey-keyboard-shortcut-to-close-the-notepad-find-results-window
; Also released at www.edcottrell.com/2014/01/11/toggle-find-results-window-notepad-hotkey/
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

; Turn F7 into a toggle for the Notepad++ search results window; currently it shows it, but doesn't hide it.
; The $ prevents this from firing itself
*$F7::
Open := 0
SetTitleMatchMode 2  ; AHK doesn't seem to recognize the window title otherwise
; See if Notepad++ is the active window or if the undocked results window (ahk_class #32770) is the active window
If WinActive("Notepad++")
{
    ; If the results pane is open, close it
    ; Button1 is the class name for the title bar and close button of the results pane when docked
    ControlGet, OutputVar, Visible,, Button1, Notepad++
    if ErrorLevel = 0
    {
        If OutputVar > 0
        {
            ; Found it docked
            Open := 1
            ; Get the size and coordinates of the title bar and button
            ControlGetPos, X, Y, Width, Height, Button1
            ; Set the coordinates of the close button
            X := Width - 9
            Y := 5
            ; Send a click
            ControlClick, Button1,,,,, NA x%X% y%Y%
        }
    }
}
; If it is undocked, use ahk_class #32770
else If WinExist("Find result ahk_class #32770")
{
    ; Found it undocked
    Open := 1
    ; Close it
    WinClose
}
; It's not open, so open it
if Open = 0
{
    SendInput {F7}
}
return

我希望这可以帮助所有喜欢它的人Notepad++！

已编辑以修复检测未停靠窗口时出现的错误。

Answer 4

从这个页面找到答案 http://forum.groovypost.com/windows-xp/lost-window-off-screen-t96201.html

• 按 F7 聚焦或打开屏幕外的窗口
• 按“Alt＆Space”，您将获得移动选项

在我的例子中，我关闭了那个窗口，当我再次搜索 doc 时，它显示在右上角，然后我把它停靠了回来！