从 Windows 命令行获取显示分辨率

Question

我已经看到了一些关于从命令行更改分辨率的程序的建议。但是我只想显示它，而不是改变它。

在 linux 上我可以使用xrandr或xdpyinfo获取这些信息，所以我正在寻找类似的东西。

我还需要它在 cygwin shell 中工作。

Answer 1

尝试这个：

wmic desktopmonitor get screenheight, screenwidth

从 Cygwin 内部：

cmd /c wmic desktopmonitor get screenheight, screenwidth

我不确定要使用什么技巧才能使用输出。也许是一个临时文本文件？

Answer 2

使用dxdiag虽然它不是最快的方法：

@echo off

del ~.txt /q /f >nul 2>nul
start "" /w dxdiag /t ~
setlocal enableDelayedExpansion
set currmon=1 
for /f "tokens=2 delims=:" %%a in ('find "Current Mode:" ~.txt') do (
    echo Monitor !currmon! : %%a
    set /a currmon=currmon+1

)
endlocal
del ~.txt /q /f >nul 2>nul

这将打印所有显示器的分辨率。

编辑。接受的答案使用 WMIC。( wmic desktopmonitor get screenheight, screenwidth /format:value). 这在 windows8/8.1/10 上不起作用。对于较新的 Windows 版本，可以使用：

wmic path Win32_VideoController get VideoModeDescription,CurrentVerticalResolution,CurrentHorizontalResolution /format:value

检查 Windows 版本然后使用 wmic 获取分辨率的脚本：

@echo off

setlocal
for /f "tokens=4,5 delims=. " %%a in ('ver') do set "version=%%a%%b"


if version lss 62 (
    ::set "wmic_query=wmic desktopmonitor get screenheight, screenwidth /format:value"
    for /f "tokens=* delims=" %%@ in ('wmic desktopmonitor get screenwidth /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "x=%%#"
    )
    for /f "tokens=* delims=" %%@ in ('wmic desktopmonitor get screenheight /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "y=%%#"
    )

) else (
    ::wmic path Win32_VideoController get VideoModeDescription,CurrentVerticalResolution,CurrentHorizontalResolution /format:value
    for /f "tokens=* delims=" %%@ in ('wmic path Win32_VideoController get CurrentHorizontalResolution  /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "x=%%#"
    )
    for /f "tokens=* delims=" %%@ in ('wmic path Win32_VideoController get CurrentVerticalResolution /format:value') do (
        for /f "tokens=2 delims==" %%# in ("%%@") do set "y=%%#"
    )

)

echo Resolution %x%x%y%

endlocal