如何使用键盘快捷键在当前文件夹中打开命令提示符？

Question

如何使用键盘快捷键在当前文件夹中打开命令提示符？

Gem*_*ili 126 windows keyboard-shortcuts autohotkey command-line

如何在 Windows 7 中使用键盘快捷键在当前文件夹中打开命令提示符？
有什么方法可以实现吗？
我认为 Autohotkey 可以做到这一点，但不知道如何。

Answer 1

Ash*_*ppa 148

按Alt+ D，键入cmd并按Enter。有关更多详细信息，请参阅此处的博客文章。

`Ctrl+L` 是另一种选择。 (5认同)
注意 - 您无需按 Alt+d 即可使用。我在 Windows 7 中所要做的就是在 Windows 资源管理器的路径中键入 cmd 并按 Enter。Alt+d 只是自动选择当前路径。 (2认同)

Answer 2

Lef*_*ium 128

使用此键盘快捷键：Shift+ Menu, W,Enter

Shift+ Menu（或者，Shift+ F10），（在当前文件夹中打开扩展的右键菜单）
W （选择“在此处打开命令窗口”），
Enter（激活选择；需要，因为“新建”也可以用选择W）

该Menu键是指由微软推出，通常在右边右侧的特殊键Win键。

此快捷方式在 Windows (7) 的默认安装中可用，无需任何 3rd 方软件。

AHK 方式。你只需要按Win+C（或任何你想定义它的东西。）：

SetTitleMatchMode RegEx
return

; Stuff to do when Windows Explorer is open
;
#IfWinActive ahk_class ExploreWClass|CabinetWClass

    ; create new text file
    ;
    #t::Send !fwt

    ; open 'cmd' in the current directory
    ;
    #c::
        OpenCmdInCurrent()
    return
#IfWinActive


; Opens the command shell 'cmd' in the directory browsed in Explorer.
; Note: expecting to be run when the active window is Explorer.
;
OpenCmdInCurrent()
{
    ; This is required to get the full path of the file from the address bar
    WinGetText, full_path, A

    ; Split on newline (`n)
    StringSplit, word_array, full_path, `n

    ; Find and take the element from the array that contains address
    Loop, %word_array0%
    {
        IfInString, word_array%A_Index%, Address
        {
            full_path := word_array%A_Index%
            break
        }
    }  

    ; strip to bare address
    full_path := RegExReplace(full_path, "^Address: ", "")

    ; Just in case - remove all carriage returns (`r)
    StringReplace, full_path, full_path, `r, , all


    IfInString full_path, \
    {
        Run,  cmd /K cd /D "%full_path%"
    }
    else
    {
        Run, cmd /K cd /D "C:\ "
    }
}

Run Code Online (Sandbox Code Playgroud)

作为奖励，上面也该脚本创建与此快捷方式的新文本文件：Win+T

信用：Eli Bendersky