访问VBA TransferSpreadsheet计数

Question

我DoCmd.TransferSpreadsheet用来填充表格.使用表单上的按钮调用此命令.传输完成后,我想告诉用户添加了多少条记录.为了尝试和完成这个我db.OpenRecordset("select * from tblImport") 然后MsgBox(rs.RecordCount)
使用问题是在传输完成之前调用记录计数.无论如何都要同步调用它？

这是完整的代码

Private Sub cmdVIT_Click()
On Error Resume Next

Dim strPath As String
Dim filePicker As FileDialog
Dim db As DAO.Database
Dim rs As DAO.Recordset

Set db = CurrentDb

Set filePicker = Application.FileDialog(msoFileDialogFilePicker)

With filePicker
    .AllowMultiSelect = False
    .ButtonName = "Select"
    .InitialView = msoFileDialogViewList
    .Title = "Select File"

    With .Filters
        .Clear
        .Add "All Files", "*.*"
    End With
    .FilterIndex = 1

    .Show
End With

strPath = filePicker.SelectedItems(1)
Debug.Print strPath
DoCmd.TransferSpreadsheet TransferType:=acImport, SpreadsheetType:=acSpreadsheetTypeExcel12, TableName:="tblImport", FileName:=strPath, HasFieldNames:=True
Set rs = db.OpenRecordset("select * from tblImport")

MsgBox rs.RecordCount & " records"
End Sub

Answer 1

你需要一个额外的线:

Set rs = db.OpenRecordset("select * from tblImport")
'Populate recordset
rs.MoveLast
MsgBox rs.RecordCount & " records"