在Base对象中构造派生类型的对象

Question

在vb.net中是否有可能有一个方法在bass类中构造任何派生类的对象？在此代码中,x.Clone应返回一个Bar对象.是两种类中使用不同对象类型的代码的唯一方法.

Module Module1

    Sub Main()
        Dim x As New Bar
        Dim y As Bar = x.Clone
    End Sub

End Module

Public Class Foo
    Implements ICloneable
    Public Function Clone() As Object Implements System.ICloneable.Clone
        Clone = Me.new() 'fails to compile as not in a constructor
        Clone = new Foo 'constructs a new foo in the derived class
    End Function
End Class

Public Class Bar
    Inherits Foo
    'additional implementation
    'but no addition fields
End Class

Answer 1

答案具体取决于您想要在克隆方法中实现的目标。

如果您想创建当前类的新实例而不实际复制任何属性（听起来您可能有兴趣根据示例代码和描述进行操作），那么简单的解决方案是：

Public Class Foo
    Implements ICloneable

    Public Function Clone() As Object Implements System.ICloneable.Clone
        Return Activator.CreateInstance(Me.GetType)
    End Function
End Class

您可以通过在 Bar 中添加消息（或某种调试或输出）来测试是否调用了此函数：

Public Class Bar
    Inherits Foo

    Public Sub New()
        MsgBox("Test")
    End Sub

End Class

如果您有Option Strict On（我强烈推荐），则 main 中的代码将是：

Sub Main()
    Dim x As New Bar
    Dim y As Bar = DirectCast(x.Clone, Bar)
End Sub

但是，如果您有兴趣从当前类复制成员值，则可以使用MemberwiseClone：

Public Class Foo
    Implements ICloneable

    Public Function Clone() As Object Implements System.ICloneable.Clone
        Return Me.MemberwiseClone
    End Function
End Class

然而，这只会创建一个浅拷贝，将复制引用，并且不会调用 Bar 上的构造函数。当我们以这种方式使用 MemberwiseClone 时，我们总是添加一个可重写的方法，继承者可以使用该方法来执行克隆后清理：

Public Class Foo
    Implements ICloneable

    Public Function Clone() As Object Implements System.ICloneable.Clone
        Dim oObject As Foo

        oObject = DirectCast(Me.MemberwiseClone, Foo)
        oObject.PostCloneCleanup()

        Return oObject
    End Function

    Protected Overridable Sub PostCloneCleanup()

    End Sub
End Class

Public Class Bar
    Inherits Foo

    Public Sub New()
        MsgBox("Test")
    End Sub

    Protected Overrides Sub PostCloneCleanup()
        MsgBox("PostCloneCleanup")
    End Sub

End Class

最后，如果浅复制或处理复制的引用不符合您的喜好，您可以使用一种廉价但非常有效的技巧来执行深复制：使用 BinaryFormatter 进行序列化和反序列化：

Public Function CreateDeepCopy(Of T)(ByVal oRecord As T) As T

    If oRecord Is Nothing Then
        Return Nothing
    End If

    If Not oRecord.GetType.IsSerializable Then
        Throw New ArgumentException(oRecord.GetType.ToString & " is not serializable")
    End If

    Dim oFormatter As New System.Runtime.Serialization.Formatters.Binary.BinaryFormatter

    Using oStream As IO.MemoryStream = New IO.MemoryStream
        oFormatter.Serialize(oStream, oRecord)
        oStream.Position = 0
        Return DirectCast(oFormatter.Deserialize(oStream), T)
    End Using
End Function

这要求类是可序列化的，但这很容易做到。