XSLT 2.0中的尾递归函数不起作用

Question

我试图在XSLT 2.0中编写一个尾递归函数,它迭代一个多值的日期变量并返回最早的日期.出于某种原因,我的函数不被SaxonHE9.4识别为尾递归,当输入文件超过150-200个条目时,我得到以下错误:

tail_rec_test.xsl第73行出错:嵌套函数调用太多.可能是由于无限递归.在内置模板规则中

这是我的xml输入:

<?xml version="1.0"?>
<Events>
  <Event>
    <Date>2004-01-01</Date>
  </Event>
  <Event>
    <Date>2003-01-01</Date>
  </Event>
  <Event>
    <Date>2002-01-01</Date>
  </Event>
  <Event>
    <Date>2001-01-01</Date>
  </Event>
  <Event>
    <Date>2005-01-01</Date>
  </Event>
  <Event>
    <Date>2006-01-01</Date>
  </Event>
  <Event>
    <Date>2007-01-01</Date>
  </Event>
  <Event>
    <Date>2008-01-01</Date>
  </Event>
</Events>

这就是我的xsl文件的样子:

<xsl:stylesheet version="2.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:fn="http://www.w3.org/2005/xpath-functions"
    xmlns:own="http://ownfunctions">
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements="*"/>


    <xsl:function name="own:findEarliestDate">
        <xsl:param name="dates" as="xs:date*"/>

        <xsl:variable name="size"><xsl:value-of select="count($dates)" /></xsl:variable>
        <xsl:choose>
            <xsl:when test="$size &gt; 0">
                <xsl:value-of select="own:findEarliestDate-helper($dates, $size, xs:date('2050-01-01'))" />
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="''"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:function>


    <xsl:function name="own:findEarliestDate-helper" as="xs:date">
        <xsl:param name="items" as="xs:date*"/>
        <xsl:param name="i" as="xs:integer"/>
        <xsl:param name="curMin" as="xs:date"/>

        <xsl:choose>
            <xsl:when
                test="$i = 0">
                <xsl:value-of select="xs:date($curMin)"/>           
            </xsl:when>
            <xsl:otherwise>
                <xsl:variable name="item" as="xs:date">
                    <xsl:value-of select="xs:date($items[$i])"/>
                </xsl:variable>

                <xsl:variable name="next" as="xs:date">
                    <xsl:choose>
                        <xsl:when test="$item &lt; $curMin">
                            <xsl:value-of select="$item"/>
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$curMin"/>
                        </xsl:otherwise>
                    </xsl:choose>
                </xsl:variable>

                <xsl:value-of select="own:findEarliestDate-helper($items, $i - 1, $next)"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:function>


    <xsl:template match="Events">
        <xsl:variable name="items" as="xs:date*">
            <xsl:for-each select="Event">
                <xsl:value-of select="xs:date(Date)"/>
            </xsl:for-each>
        </xsl:variable>

        <Test>
            <EarliestDate>
                <xsl:value-of select="own:findEarliestDate($items)"/>
            </EarliestDate>
        </Test>
    </xsl:template>

</xsl:stylesheet>

如何将其转换为正确的尾递归函数？我已经测试了这个示例,但我无法将其应用到我自己的代码中:http: //www.nesterovsky-bros.com/weblog/2008/02/20/EfficientXslt20RecursionInSaxon9.aspx

Answer 1

我无法重复这一点.

使用Saxon 9.4.06EE(评估版),结果是:

<Test xmlns:fo="http://www.w3.org/1999/XSL/Format"
      xmlns:xs="http://www.w3.org/2001/XMLSchema"
      xmlns:fn="http://www.w3.org/2005/xpath-functions"
      xmlns:own="http://ownfunctions">
   <EarliestDate>2001-01-01</EarliestDate>
</Test>

Saxon-EE 9.4.0.6J from Saxonica
Java version 1.6.0_31
Using license serial number XXXXXXXX
Generating byte code...
Stylesheet compilation time: 2168 milliseconds
Processing file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml
Using parser com.sun.org.apache.xerces.internal.jaxp.SAXParserImpl$JAXPSAXParser
Building tree for file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml using class net.sf.saxon.tree.tiny.TinyBuilder
Tree built in 10 milliseconds
Tree size: 27 nodes, 80 characters, 0 attributes
Execution time: 122ms
Memory used: 52169472
NamePool contents: 8 entries in 8 chains. 6 URIs

顺便说一下,人们可以使用它来产生相同的结果:

<xsl:value-of select="min(/*/*/Date/xs:date(.))"/>

更新:

问题出在这一行:

            <xsl:value-of select="own:findEarliestDate-helper($items, $i - 1, $next)"/>

因为函数的返回类型是xs:date,上面的行不是函数执行序列中的最后一行.它产生一个字符串(更准确地说,一个文本节点),并且XSLT处理器需要获取该字符串并将其转换为xs:date- 这意味着该函数未占用的内存不会被丢弃,并且调用堆栈将继续成长,直到它溢出.

解决方案很简单:

将以上内容替换为:

            <xsl:sequence select="own:findEarliestDate-helper($items, $i - 1, $next)"/>

这产生了一个xs:date,并且XSLT处理器现在将该函数识别为尾递归.

我用1000个事件(原始代码崩溃)测试了纠正的代码,结果正常生成(并且更快).

Saxon-EE 9.4.0.6J from Saxonica
Java version 1.6.0_31
Using license serial number XXXXXXXXXX
Generating byte code...
Stylesheet compilation time: 2002 milliseconds
Processing file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml
Using parser com.sun.org.apache.xerces.internal.jaxp.SAXParserImpl$JAXPSAXParser
Building tree for file:/C:/Program%20Files/Java/jre6/bin/marrowtr.xml using class net.sf.saxon.tree.tiny.TinyBuilder
Tree built in 124 milliseconds
Tree size: 3032 nodes, 9800 characters, 0 attributes
Execution time: 364ms
Memory used: 55089048
NamePool contents: 8 entries in 8 chains. 6 URIs