Excel VBA:将散点图作为对象添加到工作表

Question

我期待创造散点图的是,按下按钮,在创建散点图Sheet 1和使用A2:A11的x值,并B2:B11为y值.

使用底部的代码允许我根据值A1:B3(从此处获取)创建散点图.它很接近,但不完全是我正在寻找的.我该怎么调整它以满足我的需求？

我现在设置它,所以根据我想要的值制作图表,但我不能让它作为一个对象出现Sheet 1.我该怎么做呢？.Location xlLocationAsObject似乎不起作用.

Private Sub chartButton_Click()
    ActiveWorkbook.Charts.Add
    With ActiveWorkbook.ActiveChart
        'Data?
        .ChartType = xlXYScatter
        .SeriesCollection.NewSeries
        .SeriesCollection(1).Name = "=""Scatter Chart"""
        .SeriesCollection(1).XValues = "=Sheet1!$A$2:$A$11"
        .SeriesCollection(1).Values = "=Sheet1!$B$2:$B$11"

        'Location
        'DON'T KNOW WHAT TO PUT HERE
        '.location xlLocationAsObject doesn't work!

        'Titles
        .HasTitle = True
        .ChartTitle.Characters.Text = "Scatter Chart"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "X values"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Y values"
        .Axes(xlCategory).HasMajorGridlines = True

        'Formatting
        .Axes(xlCategory).HasMinorGridlines = False
        .Axes(xlValue).HasMajorGridlines = True
        .Axes(xlValue).HasMinorGridlines = False
        .HasLegend = False

    End With
End Sub

Answer 1

您编写的代码会将图表添加为a Chart Sheet,而不是作为图表添加Worksheet

试试这个:

更换

ActiveWorkbook.Charts.Add
With ActiveWorkbook.ActiveChart

同

Dim sh As Worksheet
Dim chrt As Chart

Set sh = ActiveWorkbook.Worksheets("Sheet1")
Set chrt = sh.Shapes.AddChart.Chart
With chrt

然后你可以控制它的位置和大小

    .ChartArea.Left
    .ChartArea.Top 
    .ChartArea.Height
    .ChartArea.Width