如何在Perl程序中暂时禁止STDOUT？

Question

有没有简单的方法来告诉perl"现在忽略所有打印的东西"？

我必须在外部Perl模块中调用一个过程,但该过程会打印出许多不必要的信息(通过标准打印).

我知道选择可以用来以某种方式重定向它,但我不太明智地阅读它上面的perldoc.

编辑:我很快就找到了答案,但我会添加一个例子来使它更清晰(但我猜不多)

use TectoMT::Scenario;
use TectoMT::Document;

sub tagDocuments {
    my @documents = @_;

    my $scenario = TectoMT::Scenario->new({'blocks'=> [ qw(
            SCzechW_to_SCzechM::Sentence_segmentation 
            SCzechW_to_SCzechM::Tokenize  
            SCzechW_to_SCzechM::TagHajic
            SCzechM_to_SCzechN::Czech_named_ent_SVM_recognizer) ]});

    $scenario->apply_on_tmt_documents(@documents);
    return @documents;
}

TectoMT :: Scenario和TectoMT :: Document是那些外部模块

Answer 1

我自己的答案:

use IO::Null;

print "does print.";

my $null = IO::Null;
my $oldfh = select($null); 

print "does not print.";

select($oldfh);

print "does print.";

Answer 2

我意识到这已得到回答,但我认为值得了解另一种方法.特别是如果在打印时出现问题STDOUT......

# Store anything written to STDOUT in a string.
my $str;
open my $fh, '>', \$str;
{
  local *STDOUT = $fh;
  code_that_prints_to_stdout();
}

关键是local *STDOUT.它用STDOUT您选择的文件句柄替换法线,但仅限于包含本地的块的范围.

Answer 3

在这里和其他线索中提到了一些答案,我提出了这个问题;

use strict;
use warnings;
use File::Spec;

sub my_functor { system("some_noisy_command.exe", "--option1", "--option2"); }
silently(\&my_functor);

其中"silentntly()"接受一个仿函数并使用stdout重定向运行它:

sub silently($) {
    #Turn off STDOUT
    open my $saveout, ">&STDOUT";
    open STDOUT, '>', File::Spec->devnull();

    #Run passed function
    my $func = $_[0];
    $func->();

    #Restore STDOUT
    open STDOUT, ">&", $saveout;
}